From e59dfa379b653022220eb819aa1de50f9feeef1f Mon Sep 17 00:00:00 2001
From: law <law@138bc75d-0d04-0410-961f-82ee72b054a4>
Date: Tue, 16 Sep 1997 04:55:29 +0000
Subject:         * aclocal.m4: New file with replacement for AC_PROG_INSTALL. 
        * configure.in: Use EGCS_PROG_INSTALL.

git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@15471 138bc75d-0d04-0410-961f-82ee72b054a4
---
 etc/ChangeLog    |  5 +++++
 etc/aclocal.m4   | 62 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 etc/configure.in |  2 +-
 3 files changed, 68 insertions(+), 1 deletion(-)
 create mode 100644 etc/aclocal.m4

(limited to 'etc')

diff --git a/etc/ChangeLog b/etc/ChangeLog
index 54c1a44f24a..13d1fc2ebee 100644
--- a/etc/ChangeLog
+++ b/etc/ChangeLog
@@ -1,3 +1,8 @@
+Mon Sep 15 22:53:01 1997  Jeffrey A Law  (law@cygnus.com)
+
+	* aclocal.m4: New file with replacement for AC_PROG_INSTALL.
+	* configure.in: Use EGCS_PROG_INSTALL.
+
 Tue Jun 17 15:50:23 1997  Angela Marie Thomas (angela@cygnus.com)
 
 	* Install.in: Add /usr/bsd to PATH for Irix (home of compress)
diff --git a/etc/aclocal.m4 b/etc/aclocal.m4
new file mode 100644
index 00000000000..18c8235ec9b
--- /dev/null
+++ b/etc/aclocal.m4
@@ -0,0 +1,62 @@
+AC_DEFUN(EGCS_PROG_INSTALL,
+[AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
+# Find a good install program.  We prefer a C program (faster),
+# so one script is as good as another.  But avoid the broken or
+# incompatible versions:
+# SysV /etc/install, /usr/sbin/install
+# SunOS /usr/etc/install
+# IRIX /sbin/install
+# AIX /bin/install
+# AFS /usr/afsws/bin/install, which mishandles nonexistent args
+# SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
+# ./install, which can be erroneously created by make from ./install.sh.
+AC_MSG_CHECKING(for a BSD compatible install)
+if test -z "$INSTALL"; then
+AC_CACHE_VAL(ac_cv_path_install,
+[  IFS="${IFS= 	}"; ac_save_IFS="$IFS"; IFS="${IFS}:"
+  for ac_dir in $PATH; do
+    # Account for people who put trailing slashes in PATH elements.
+    case "$ac_dir/" in
+    /|./|.//|/etc/*|/usr/sbin/*|/usr/etc/*|/sbin/*|/usr/afsws/bin/*|/usr/ucb/*) ;;
+    *)
+      # OSF1 and SCO ODT 3.0 have their own names for install.
+      for ac_prog in ginstall scoinst install; do
+        if test -f $ac_dir/$ac_prog; then
+	  if test $ac_prog = install &&
+            grep dspmsg $ac_dir/$ac_prog >/dev/null 2>&1; then
+	    # AIX install.  It has an incompatible calling convention.
+	    # OSF/1 installbsd also uses dspmsg, but is usable.
+	    :
+	  else
+	    ac_cv_path_install="$ac_dir/$ac_prog -c"
+	    break 2
+	  fi
+	fi
+      done
+      ;;
+    esac
+  done
+  IFS="$ac_save_IFS"
+])dnl
+  if test "${ac_cv_path_install+set}" = set; then
+    INSTALL="$ac_cv_path_install"
+  else
+    # As a last resort, use the slow shell script.  We don't cache a
+    # path for INSTALL within a source directory, because that will
+    # break other packages using the cache if that directory is
+    # removed, or if the path is relative.
+    INSTALL="$ac_install_sh"
+  fi
+fi
+dnl We do special magic for INSTALL instead of AC_SUBST, to get
+dnl relative paths right.
+AC_MSG_RESULT($INSTALL)
+
+# Use test -z because SunOS4 sh mishandles braces in ${var-val}.
+# It thinks the first close brace ends the variable substitution.
+test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
+AC_SUBST(INSTALL_PROGRAM)dnl
+
+test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
+AC_SUBST(INSTALL_DATA)dnl
+])
diff --git a/etc/configure.in b/etc/configure.in
index b785068009e..9176273de25 100644
--- a/etc/configure.in
+++ b/etc/configure.in
@@ -2,6 +2,6 @@ dnl Process this file with autoconf to produce a configure script.
 AC_PREREQ(2.5)
 AC_INIT(Makefile.in)
 
-AC_PROG_INSTALL
+EGCS_PROG_INSTALL
 
 AC_OUTPUT(Makefile)
-- 
cgit v1.2.3