Changes: add mAddLibrary function, use it in .pro files

RevBy: Armin, Mirek
Details: To simplify addition of a link library to a
project for the different platforms, we need this function.

Initial patch by Thierry Bastian.

4 files changed, 24 insertions, 25 deletions

diff --git a/mkspecs/features/meegotouch.prf b/mkspecs/features/meegotouch.prf
index 8718f013..f9f4883a 100644
--- a/mkspecs/features/meegotouch.prf
+++ b/mkspecs/features/meegotouch.prf
@@ -1,13 +1,10 @@
 include(meegotouch_common.prf)
 
-macx {
-    LIBS += \
-        -framework meegotouchcore
-} else {
+LIBS += $$mAddLibrary(meegotouchcore)
+!macx {
     !contains(DEFINES, BUILD_M) {
         LIBS += \
-	    -lmeegotouchcore \
-	    -lmeegotouchsettings \
-	    -lmeegotouchextensions
+	    $$mAddLibrary(meegotouchsettings) \
+	    $$mAddLibrary(meegotouchextensions)
     }
 }
diff --git a/mkspecs/features/meegotouch_defines.prf.in b/mkspecs/features/meegotouch_defines.prf.in
index e0daa77d..86f6f6d2 100644
--- a/mkspecs/features/meegotouch_defines.prf.in
+++ b/mkspecs/features/meegotouch_defines.prf.in
@@ -108,3 +108,20 @@ win32 {
     M_DBUS_INTERFACES_DIR = /usr/share/dbus-1/interfaces
     M_DBUS_SERVICES_DIR = $$M_INSTALL_DATA/dbus-1/services
 }
+
+defineReplace(mAddLibrary) {
+    LIBRARY_NAME = $$1
+    macx {
+        QMAKE_LFLAGS *= -F $$M_BUILD_TREE/lib
+        return (-framework $$LIBRARY_NAME)
+    } else {
+        win32 {
+            CONFIG(debug, debug|release) {
+                return ("-l"$${LIBRARY_NAME}d$${M_MAJOR_VERSION})
+            } else {
+                return ("-l"$${LIBRARY_NAME}$${M_MAJOR_VERSION})
+            }
+        }
+        return (-l$$LIBRARY_NAME)
+    }
+}
diff --git a/mkspecs/features/meegotouchcore.prf b/mkspecs/features/meegotouchcore.prf
index ed958b36..b69165cc 100644
--- a/mkspecs/features/meegotouchcore.prf
+++ b/mkspecs/features/meegotouchcore.prf
@@ -1,9 +1,3 @@
 include(meegotouch_common.prf)
 
-macx {
-    LIBS += -framework meegotouchcore
-} else {
-    !contains(DEFINES, BUILD_M) {
-        LIBS += -lmeegotouchcore
-    }
-}
+LIBS += $$mAddLibrary(meegotouchcore)
diff --git a/mkspecs/features/meegotouchsettings.prf b/mkspecs/features/meegotouchsettings.prf
index 1018e1a4..65c93fad 100644
--- a/mkspecs/features/meegotouchsettings.prf
+++ b/mkspecs/features/meegotouchsettings.prf
@@ -1,13 +1,4 @@
 include(meegotouch_common.prf)
 
-macx {
-    LIBS += \
-        -framework meegotouchcore \
-        -framework meegotouchsettings \
-} else {
-    !contains(DEFINES, BUILD_M) {
-        LIBS += \
-	    -lmeegotouchcore \
-	    -lmeegotouchsettings \
-    }
-}
+LIBS += $$mAddLibrary(meegotouchcore) \
+        $$mAddLibrary(meegotouchsettings)