@echo on
setlocal

REM Script for building the LLVM installer on Windows,
REM used for the the weekly snapshots at http://www.llvm.org/builds.
REM
REM Usage: build_llvm_package.bat <revision> [test]

REM Prerequisites:
REM
REM   Visual Studio 2019, CMake, Ninja, GNUWin32, SWIG, Python 3,
REM   NSIS with the strlen_8192 patch,
REM   Visual Studio 2019 SDK and Nuget (for the clang-format plugin),
REM   Perl (for the OpenMP run-time), 7Zip.
REM
REM
REM   For LLDB, SWIG version <= 3.0.8 needs to be used to work around
REM   https://github.com/swig/swig/issues/769


REM You need to modify the paths below:
set vsdevcmd=C:\Program Files (x86)\Microsoft Visual Studio\2019\BuildTools\Common7\Tools\VsDevCmd.bat

set python32_dir=C:\Users\%USERNAME%\AppData\Local\Programs\Python\Python36-32
set python64_dir=C:\Users\%USERNAME%\AppData\Local\Programs\Python\Python36

for /f "usebackq" %%i in (`PowerShell ^(Get-Date^).ToString^('yyyyMMdd'^)`) do set datestamp=%%i

set revision=%1

if "%2" == "test" (
    set git_ref=%revision%
    set package_version=%revision:~0,8%
) else (
    set git_ref=llvmorg-%revision%
    set package_version=%revision%
)

REM Extract the release version from a revision of the kind x.y.z-rcN
REM FIXME: Handle other kinds of revisions
REM FIXME: Error out if we get smth inappropriate.
for /f "delims=-" %%i in ("%revision%") do (
  set release_version=%%i
)

set clang_format_vs_version=13.0.0.%datestamp%
set build_dir=llvm_package_%package_version%

echo Revision: %revision%
echo Package version: %package_version%
echo Clang format plugin version: %clang_format_vs_version%
echo Build dir: %build_dir%
echo.
REM pause

mkdir %build_dir%
cd %build_dir%

echo Checking out %git_ref%
curl -L https://github.com/llvm/llvm-project/archive/%git_ref%.zip -o src.zip || exit /b
7z x src.zip || exit /b
mv llvm-project-* llvm-project || exit /b

REM Setting CMAKE_CL_SHOWINCLUDES_PREFIX to work around PR27226.
set cmake_flags=^
  -DCMAKE_BUILD_TYPE=Release ^
  -DCMAKE_TRY_COMPILE_CONFIGURATION=Release ^
  -DLLVM_ENABLE_ASSERTIONS=ON ^
  -DLLVM_INSTALL_TOOLCHAIN_ONLY=ON ^
  -DLLVM_BUILD_LLVM_C_DYLIB=ON ^
  -DCMAKE_INSTALL_UCRT_LIBRARIES=ON ^
  -DPACKAGE_VERSION=%package_version% ^
  -DCMAKE_CL_SHOWINCLUDES_PREFIX="Note: including file: " ^
  -DLLVM_DEFAULT_TARGET_TRIPLE=aarch64-pc-windows-msvc ^
  -DLLVM_HOST_TRIPLE=aarch64-pc-windows-msvc ^
  -DLLVM_TARGET_ARCH=AArch64 ^
  -DCLANG_DEFAULT_LINKER=lld

REM TODO: Run the "check-all" tests.

set "VSCMD_START_DIR=%CD%"
call "%vsdevcmd%" -host_arch=x86 -arch=arm64
@echo on
set CC=clang-cl
set CXX=clang-cl
mkdir build32_stage0
cd build32_stage0
REM Note that we only enable compiler-rt so we can build the builtins, which are
REM needed in the next stage when building flang
cmake -GNinja %cmake_flags% ^
  -DLLVM_ENABLE_PROJECTS="clang;clang-tools-extra;lld;compiler-rt" ^
  -DLLVM_TARGETS_TO_BUILD="AArch64" ^
  -DCMAKE_C_FLAGS="-fms-compatibility-version=19.20" ^
  -DCMAKE_CXX_FLAGS="-fms-compatibility-version=19.20" ^
  -DCMAKE_COMPILER_RT_BUILD_BUILTINS=ON ^
  -DCMAKE_COMPILER_RT_BUILD_CRT=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_SANITIZERS=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_XRAY=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_LIBFUZZER=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_PROFILE=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_MEMPROF=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_ORC=OFF ^
  -DCMAKE_COMPILER_RT_BUILD_GWP_ASAN=OFF ^
  ..\llvm-project\llvm || exit /b
ninja all || ninja all || ninja all || exit /b
REM ninja check || ninja check || ninja check || exit /b
REM ninja check-clang || ninja check-clang || ninja check-clang || exit /b
REM ninja check-lld || ninja check-lld || ninja check-lld || exit /b
REM ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b
REM ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b
REM ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b
cd..

mkdir build32
cd build32
set CC=..\build32_stage0\bin\clang-cl
set CXX=..\build32_stage0\bin\clang-cl
set builtins=%cd%\..\build32_stage0\lib\clang\%release_version%\lib\windows\clang_rt.builtins-aarch64.lib
set "LLDB_USE_LLDB_SERVER=1"
cmake -GNinja %cmake_flags% ^
  -DLLVM_ENABLE_PROJECTS="clang;clang-tools-extra;flang;lld;lldb;compiler-rt" ^
  -DCMAKE_C_FLAGS="-fms-compatibility-version=19.20" ^
  -DCMAKE_CXX_FLAGS="-fms-compatibility-version=19.20" ^
  -DCOMPILER_RT_BUILD_SANITIZERS=OFF ^
  -DCOMPILER_RT_BUILD_MEMPROF=OFF ^
  -DCOMPILER_RT_BUILD_XRAY=OFF ^
  -DLLDB_ENABLE_PYTHON=ON ^
  -DLLDB_RELOCATABLE_PYTHON=ON ^
  -DLLDB_EMBED_PYTHON_HOME=OFF ^
  -DCMAKE_EXE_LINKER_FLAGS=%builtins% ^
  -DCMAKE_SHARED_LINKER_FLAGS=%builtins% ^
  -DCMAKE_STATIC_LINKER_FLAGS=%builtins% ^
  -DLLDB_TEST_USER_ARGS="--skip-category=watchpoint" ^
  -DCMAKE_MODULE_LINKER_FLAGS=%builtins% ^
  ..\llvm-project\llvm || exit /b
ninja all || ninja all || ninja all || exit /b
ninja check-lldb || ninja check-lldb || ninja check-lldb
ninja check-flang || ninja check-flang || ninja check-flang
REM ninja check || ninja check || ninja check || exit /b
REM ninja check-clang || ninja check-clang || ninja check-clang || exit /b
REM ninja check-lld || ninja check-lld || ninja check-lld || exit /b
REM ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b
REM ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b
REM ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b
ninja package || exit /b

rename LLVM-%package_version%-win64.exe LLVM-%package_version%-woa64.exe || exit /b
7z x LLVM-%package_version%-woa64.exe -orepack || exit /b
rmdir /s /q repack\$PLUGINSDIR || exit /b
del repack\Uninstall.exe || exit /b
7z a LLVM-%package_version%-woa64.zip .\repack\* -mx9 || exit /b
cd ..

exit /b

REM The plug-in is built separately as it uses a statically linked clang-format.exe.
mkdir build_vsix
cd build_vsix
REM Having VSSDKINSTALL set makes devenv *not* find the SDK for some reason.
set VSSDKINSTALL=
set CC=..\build32_stage0\bin\clang-cl
set CXX=..\build32_stage0\bin\clang-cl
cmake -GNinja %cmake_flags% -DLLVM_USE_CRT_RELEASE=MT -DBUILD_CLANG_FORMAT_VS_PLUGIN=ON -DPYTHON_HOME=%python32_dir% -DPYTHON_EXECUTABLE=%python32_dir%\python.exe ..\llvm-project\llvm || exit /b
ninja clang_format_vsix || exit /b
copy ..\llvm-project\llvm\tools\clang\tools\clang-format-vs\ClangFormat\bin\Release\ClangFormat.vsix ClangFormat-r%revision%.vsix
cd ..


set "VSCMD_START_DIR=%CD%"
call "%vsdevcmd%" -arch=amd64
set CC=
set CXX=
mkdir build64_stage0
cd build64_stage0
cmake -GNinja %cmake_flags% -DPYTHON_HOME=%python64_dir% -DPYTHON_EXECUTABLE=%python64_dir%\python.exe ..\llvm-project\llvm || exit /b
ninja all || ninja all || ninja all || exit /b
ninja check || ninja check || ninja check || exit /b
ninja check-clang || ninja check-clang || ninja check-clang || exit /b
ninja check-lld || ninja check-lld || ninja check-lld || exit /b
ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b
ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b
ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b
cd..

mkdir build64
cd build64
set CC=..\build64_stage0\bin\clang-cl
set CXX=..\build64_stage0\bin\clang-cl
cmake -GNinja %cmake_flags% -DPYTHON_HOME=%python64_dir% -DPYTHON_EXECUTABLE=%python64_dir%\python.exe ..\llvm-project\llvm || exit /b
ninja all || ninja all || ninja all || exit /b
ninja check || ninja check || ninja check || exit /b
ninja check-clang || ninja check-clang || ninja check-clang || exit /b
ninja check-lld || ninja check-lld || ninja check-lld || exit /b
ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b
ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b
ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b
ninja package || exit /b

7z x LLVM-%package_version%-win64.exe -orepack
rmdir /s /q repack\$PLUGINSDIR
del repack\Uninstall.exe
7z a LLVM-%package_version%-win64.zip .\repack\* -mx9
cd ..