4 files changed, 589 insertions, 0 deletions
diff --git a/misc/nsis/Makefile b/misc/nsis/Makefile
new file mode 100644
index 0000000..4405f0f
--- /dev/null
+++ b/misc/nsis/Makefile
@@ -0,0 +1,15 @@
+VERSION=1.35_SVN
+RELEASE=0
+
+all: ioquake3-$(VERSION)-$(RELEASE).x86.exe
+
+ioquake3.nsi: ioquake3.nsi.in
+	sed 's/XXXVERSIONXXX/$(VERSION)/;s/XXXRELEASEXXX/$(RELEASE)/' < $< > $@
+
+ioquake3-$(VERSION)-$(RELEASE).x86.exe: ioquake3.nsi
+	makensis ioquake3.nsi
+
+clean:
+	rm -rf *.exe ioquake3.nsi
+
+.PHONY: all clean
diff --git a/misc/nsis/ioquake3-q3a.nsi b/misc/nsis/ioquake3-q3a.nsi
new file mode 100644
index 0000000..9975609
--- /dev/null
+++ b/misc/nsis/ioquake3-q3a.nsi
@@ -0,0 +1,248 @@
+; NSIS description file for quake3 data file installer
+
+SetCompressor lzma
+
+!define NAME "Quake III Arena"
+!define FSNAME "ioquake3-q3a"
+!define VERSION "1.32"
+!define RELEASE "1"
+
+!define MULTIUSER_MUI
+!define MULTIUSER_EXECUTIONLEVEL Highest
+!define MULTIUSER_INSTALLMODE_COMMANDLINE
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "Install_Mode"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME "Install_Dir"
+!define MULTIUSER_INSTALLMODE_INSTDIR "ioquake3"
+!include MultiUser.nsh
+
+!include "FileFunc.nsh"
+Var q3a_pak0
+Var q3ta_pak0
+
+!include "MUI2.nsh"
+!define MUI_ICON "../quake3.ico"
+
+; The name of the installer
+Name "${NAME}-${VERSION} for ioquake3"
+
+; The file to write
+OutFile "${FSNAME}-${VERSION}-${RELEASE}.x86.exe"
+
+;Interface Settings
+
+!define MUI_ABORTWARNING
+
+;--------------------------------
+;Pages
+
+!insertmacro MULTIUSER_PAGE_INSTALLMODE
+!insertmacro MUI_PAGE_LICENSE "id_patch_pk3s_Q3A_EULA.txt"
+!insertmacro MUI_PAGE_COMPONENTS
+!insertmacro MUI_PAGE_DIRECTORY
+!insertmacro MUI_PAGE_INSTFILES
+
+!insertmacro MUI_UNPAGE_CONFIRM
+!insertmacro MUI_UNPAGE_COMPONENTS
+!insertmacro MUI_UNPAGE_INSTFILES
+
+;--------------------------------
+;Languages
+
+!insertmacro MUI_LANGUAGE "English"
+
+;--------------------------------
+
+;--------------------------------
+;Multiuser stuff
+Function .onInit
+  !insertmacro MULTIUSER_INIT
+  StrCpy $q3a_pak0 "notfound"
+  ReadRegStr $0 SHCTX "Software\ioquake3" ${MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME}
+  IfErrors 0 oninitdone
+    MessageBox MB_OK "You need to install the ioquake3 engine first"
+    Abort
+  oninitdone:
+FunctionEnd
+
+Function un.onInit
+  !insertmacro MULTIUSER_UNINIT
+FunctionEnd
+
+; The stuff to install
+Section "${NAME}" sec_q3a
+
+  SectionIn RO
+
+  SetOutPath $INSTDIR
+  File "id_patch_pk3s_Q3A_EULA.txt"
+
+  SetOutPath "$INSTDIR\baseq3"
+  File "baseq3/pak1.pk3"
+  File "baseq3/pak2.pk3"
+  File "baseq3/pak3.pk3"
+  File "baseq3/pak4.pk3"
+  File "baseq3/pak5.pk3"
+  File "baseq3/pak6.pk3"
+  File "baseq3/pak7.pk3"
+  File "baseq3/pak8.pk3"
+
+  ; Write the uninstall keys for Windows
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "DisplayName" "${NAME}"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "UninstallString" '"$INSTDIR\uninstall-${FSNAME}.exe"'
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "NoModify" 1
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "NoRepair" 1
+  WriteUninstaller "uninstall-${FSNAME}.exe"
+
+SectionEnd
+
+Section /o "${NAME} CDROM" sec_q3acd
+	AddSize 468992
+	q3apak0retry:
+	ClearErrors
+	StrCmp $q3a_pak0 "notfound" 0 q3apak0copy
+		call findq3acd
+	q3apak0copy:
+	CopyFiles $q3a_pak0 "$INSTDIR\baseq3"
+	IfErrors 0 q3apak0done
+		MessageBox MB_RETRYCANCEL "Copying the Quake III Arena pak0.pk3 file failed. Make sure the correct CD is in the drive" IDRETRY q3apak0retry IDCANCEL q3apak0cancel
+	goto q3apak0done
+	q3apak0cancel:
+		Abort
+	q3apak0done:
+SectionEnd
+
+Function findq3acd
+	StrCpy $q3a_pak0 "notfound"
+	${GetDrives} "CDROM" "findq3acd_cb"
+FunctionEnd
+
+Function findq3acd_cb
+	StrCpy $R1 "$9baseq3\pak0.pk3"
+	IfFileExists $R1 q3acd_cb_found 0
+	StrCpy $R1 "$9quake3\baseq3\pak0.pk3"
+	IfFileExists $R1 0 q3acd_cb_done
+q3acd_cb_found:
+	StrCpy $q3a_pak0 $R1
+	StrCpy $0 StopGetDrives
+
+q3acd_cb_done:
+	Push $0
+FunctionEnd
+
+Section "Quake III Team Arena" sec_q3ta
+
+  SetOutPath "$INSTDIR\missionpack"
+
+  File "missionpack/pak1.pk3"
+  File "missionpack/pak2.pk3"
+  File "missionpack/pak3.pk3"
+
+  CreateShortCut "$SMPROGRAMS\ioquake3\Team Arena.lnk" "$INSTDIR\ioquake3.x86.exe" "+set fs_game missionpack" "$INSTDIR\ioquake3.x86.exe" 0 "" "" "Team Arena"
+
+SectionEnd
+
+Section /o "Quake III Team Arena CDROM" sec_q3tacd
+	AddSize 344064
+	q3tapak0retry:
+	ClearErrors
+	StrCmp $q3ta_pak0 "notfound" 0 q3tapak0copy
+		call findq3tacd
+	q3tapak0copy:
+	CopyFiles $q3ta_pak0 "$INSTDIR\missionpack"
+	IfErrors 0 q3tapak0done
+		MessageBox MB_RETRYCANCEL "Copying the Quake III TeamArena pak0.pk3 file failed. Make sure the correct CD is in the drive" IDRETRY q3tapak0retry IDCANCEL q3tapak0cancel
+	goto q3tapak0done
+	q3tapak0cancel:
+		Abort
+	q3tapak0done:
+SectionEnd
+
+Function findq3tacd
+	StrCpy $q3ta_pak0 "notfound"
+	${GetDrives} "CDROM" "findq3tacd_cb"
+FunctionEnd
+
+Function findq3tacd_cb
+	StrCpy $R1 "$9Setup\missionpack\pak0.pk3"
+	IfFileExists $R1 0 q3tacd_cb_done
+	StrCpy $q3ta_pak0 $R1
+	StrCpy $0 StopGetDrives
+q3tacd_cb_done:
+	Push $0
+FunctionEnd
+
+;--------------------------------
+
+; Uninstaller
+
+Section "un.Quake III Arena and Team Arena" sec_un_q3a
+
+  SectionIn RO
+
+  ; Remove registry keys
+  DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}"
+
+  ; Remove files and uninstaller
+  Delete $INSTDIR\baseq3\pak1.pk3
+  Delete $INSTDIR\baseq3\pak2.pk3
+  Delete $INSTDIR\baseq3\pak3.pk3
+  Delete $INSTDIR\baseq3\pak4.pk3
+  Delete $INSTDIR\baseq3\pak5.pk3
+  Delete $INSTDIR\baseq3\pak6.pk3
+  Delete $INSTDIR\baseq3\pak7.pk3
+  Delete $INSTDIR\baseq3\pak8.pk3
+  
+  Delete $INSTDIR\missionpack\pak1.pk3
+  Delete $INSTDIR\missionpack\pak2.pk3
+  Delete $INSTDIR\missionpack\pak3.pk3
+
+  Delete $INSTDIR\uninstall-${FSNAME}.exe
+
+  Delete "$INSTDIR\id_patch_pk3s_Q3A_EULA.txt"
+
+  ; Remove shortcuts, if any
+  Delete "$SMPROGRAMS\ioquake3\Team Arena.lnk"
+
+  ; Remove directories used
+  RMDir "$SMPROGRAMS\ioquake3"
+  RMDir "$INSTDIR\baseq3"
+  RMDir "$INSTDIR\missionpack"
+  RMDir "$INSTDIR"
+
+SectionEnd
+
+Section "un.CDROM Data" sec_un_q3a_cd
+  Delete $INSTDIR\baseq3\pak0.pk3
+  Delete $INSTDIR\missionpack\pak0.pk3
+  RMDir "$INSTDIR\baseq3"
+  RMDir "$INSTDIR\missionpack"
+  RMDir "$INSTDIR"
+SectionEnd
+
+Function .onSelChange
+	${If} ${SectionIsSelected} ${sec_q3acd}
+		Call findq3acd
+		StrCmp $q3a_pak0 "notfound" 0 +2
+			MessageBox MB_OK "Quake III Arena CD not found. Make sure it is in the drive otherwise installation will fail"
+	${EndIf}
+	${If} ${SectionIsSelected} ${sec_q3tacd}
+		Call findq3tacd
+		StrCmp $q3ta_pak0 "notfound" 0 +2
+			MessageBox MB_OK "Quake III TeamArena CD not found. Make sure it is in the drive otherwise installation will fail"
+	${EndIf}
+FunctionEnd
+
+
+LangString DESC_q3a ${LANG_ENGLISH} "Install official Quake III Arena Point Release 1.32 data files. Note that the data files alone are useless. You need to also install the Quake III Arena base assets (pak0.pk3) from the game's CD-ROM."
+LangString DESC_q3acd ${LANG_ENGLISH} "Install the Quake III Arena base assets (pak0.pk3) from the game's CD-ROM."
+LangString DESC_q3ta ${LANG_ENGLISH} "Install official Quake III Team Arena Point Release 1.32 data files. Note that the data files alone are useless. You need to also install the Quake III Team Arena base assets (pak0.pk3) from the game's CD-ROM."
+LangString DESC_q3tacd ${LANG_ENGLISH} "Install the Quake III Team Arena base assets (pak0.pk3) from the game's CD-ROM."
+
+!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
+  !insertmacro MUI_DESCRIPTION_TEXT ${sec_q3a} $(DESC_q3a)
+  !insertmacro MUI_DESCRIPTION_TEXT ${sec_q3acd} $(DESC_q3acd)
+  !insertmacro MUI_DESCRIPTION_TEXT ${sec_q3ta} $(DESC_q3ta)
+  !insertmacro MUI_DESCRIPTION_TEXT ${sec_q3tacd} $(DESC_q3tacd)
+!insertmacro MUI_FUNCTION_DESCRIPTION_END
diff --git a/misc/nsis/ioquake3-q3ctc.nsi b/misc/nsis/ioquake3-q3ctc.nsi
new file mode 100644
index 0000000..e4f27e3
--- /dev/null
+++ b/misc/nsis/ioquake3-q3ctc.nsi
@@ -0,0 +1,140 @@
+; sample NSIS description file for a ioquake3 mod installer
+
+!define NAME "Catch the Chicken"
+!define FSNAME "ioquake3-q3ctc"
+!define VERSION "1.4"
+!define RELEASE "1"
+!define MODDIR "q3ctc"
+!define PUBLISHER "The ioquake3 Team"
+!define URL "http://ioquake3.org/"
+; uncomment if the mod works without baseq3
+;!define STANDALONE
+
+!define MUI_ICON "../quake3.ico"
+
+!macro FILES
+  File ctc0.pk3
+  File ctc1.pk3
+  File description.txt
+  File gfx/chicken.jpg
+  File gfx/egggun.jpg
+  File gfx/q3ctc.gif
+  File q3ctc.config
+  File q3ctcteam.config
+  File readme.html
+  File readmeFirst.txt
+!macroend
+
+; no need to edit below in theory
+
+SetCompressor lzma
+
+!define MULTIUSER_MUI
+!define MULTIUSER_EXECUTIONLEVEL Highest
+!define MULTIUSER_INSTALLMODE_COMMANDLINE
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "Install_Mode"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME "Install_Dir"
+!define MULTIUSER_INSTALLMODE_INSTDIR "ioquake3"
+!include MultiUser.nsh
+
+!include "FileFunc.nsh"
+
+!include "MUI2.nsh"
+
+; The name of the installer
+Name "${NAME}-${VERSION} for ioquake3"
+
+; The file to write
+OutFile "${FSNAME}-${VERSION}-${RELEASE}.x86.exe"
+
+;Interface Settings
+
+!define MUI_ABORTWARNING
+
+;--------------------------------
+;Pages
+
+!insertmacro MULTIUSER_PAGE_INSTALLMODE
+;!insertmacro MUI_PAGE_LICENSE "id_patch_pk3s_Q3A_EULA.txt"
+!define MUI_COMPONENTSPAGE_NODESC
+!insertmacro MUI_PAGE_COMPONENTS
+!insertmacro MUI_PAGE_DIRECTORY
+!insertmacro MUI_PAGE_INSTFILES
+
+!insertmacro MUI_UNPAGE_CONFIRM
+!insertmacro MUI_UNPAGE_INSTFILES
+
+;--------------------------------
+;Languages
+
+!insertmacro MUI_LANGUAGE "English"
+
+;--------------------------------
+
+;--------------------------------
+;Multiuser stuff
+Function .onInit
+  !insertmacro MULTIUSER_INIT
+  ReadRegStr $0 SHCTX "Software\ioquake3" ${MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME}
+  IfErrors 0 oninitdone
+    MessageBox MB_OK "You need to install the ioquake3 engine first"
+    Abort
+  oninitdone:
+FunctionEnd
+
+Function un.onInit
+  !insertmacro MULTIUSER_UNINIT
+FunctionEnd
+
+; The stuff to install
+Section "${NAME}" sec_base
+
+  SectionIn RO
+
+  SetOutPath $INSTDIR
+
+  SetOutPath "$INSTDIR\${MODDIR}"
+
+  !insertmacro FILES
+
+  ; Write the uninstall keys for Windows
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "DisplayName" "${NAME}"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "DisplayVersion" "${VERSION}-${RELEASE}"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "Publisher" "${PUBLISHER}"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "URLInfoAbout" "${URL}"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "UninstallString" '"$INSTDIR\uninstall-${FSNAME}.exe"'
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "NoModify" 1
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}" "NoRepair" 1
+
+  WriteUninstaller "uninstall-${FSNAME}.exe"
+
+!ifdef STANDALONE
+!define ARGS "+set com_standalone 1 "
+!else
+!define ARGS ""
+!endif
+  CreateShortCut "$SMPROGRAMS\ioquake3\${NAME}.lnk" "$INSTDIR\ioquake3.x86.exe" "${ARGS}+set fs_game ${MODDIR}" "$INSTDIR\ioquake3.x86.exe" 0 "" "" "${NAME}"
+
+SectionEnd
+
+Section "Uninstall"
+
+  ; Remove registry keys
+  DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${FSNAME}"
+
+  ; Remove files and uninstaller
+  Delete $INSTDIR\${MODDIR}\*
+  
+  Delete $INSTDIR\uninstall-${FSNAME}.exe
+
+  ; Remove shortcuts, if any
+  Delete "$SMPROGRAMS\ioquake3\${NAME}.lnk"
+
+  ; Remove directories used
+  RMDir "$SMPROGRAMS\ioquake3"
+  RMDir "$INSTDIR\${MODDIR}"
+  RMDir "$INSTDIR"
+
+SectionEnd
diff --git a/misc/nsis/ioquake3.nsi.in b/misc/nsis/ioquake3.nsi.in
new file mode 100644
index 0000000..ddf2090
--- /dev/null
+++ b/misc/nsis/ioquake3.nsi.in
@@ -0,0 +1,186 @@
+; NSIS description file for ioquake3 installer
+;
+; EDIT WITH CARE!
+;
+; This file is used to automatically build the installers in the
+; openSUSE build service, don't break this!
+;
+; you have to copy SDL.dll and libcurl-4.dll here manually
+
+!define MULTIUSER_MUI
+!define MULTIUSER_EXECUTIONLEVEL Highest
+!define MULTIUSER_INSTALLMODE_COMMANDLINE
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "Install_Mode"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_KEY "Software\ioquake3"
+!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME "Install_Dir"
+!define MULTIUSER_INSTALLMODE_INSTDIR "ioquake3"
+!include MultiUser.nsh
+
+!include "MUI2.nsh"
+!define MUI_ICON "../quake3.ico"
+
+; The name of the installer
+Name "ioquake3"
+
+; The file to write
+OutFile "ioquake3-XXXVERSIONXXX-XXXRELEASEXXX.x86.exe"
+
+; The default installation directory
+; set by Multiuser.nsh
+;InstallDir $PROGRAMFILES\ioquake3
+
+; Registry key to check for directory (so if you install again, it will
+; overwrite the old one automatically)
+; handled by Multiuser.nsh
+;InstallDirRegKey HKLM "Software\ioquake3" "Install_Dir"
+
+;--------------------------------
+;Interface Settings
+
+!define MUI_ABORTWARNING
+
+;--------------------------------
+;Pages
+
+!insertmacro MULTIUSER_PAGE_INSTALLMODE
+#!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"
+!insertmacro MUI_PAGE_COMPONENTS
+!insertmacro MUI_PAGE_DIRECTORY
+!insertmacro MUI_PAGE_INSTFILES
+
+!insertmacro MUI_UNPAGE_CONFIRM
+!insertmacro MUI_UNPAGE_INSTFILES
+
+;--------------------------------
+;Languages
+
+!insertmacro MUI_LANGUAGE "English"
+
+;--------------------------------
+
+;--------------------------------
+;Multiuser stuff
+Function .onInit
+  !insertmacro MULTIUSER_INIT
+FunctionEnd
+
+Function un.onInit
+  !insertmacro MULTIUSER_UNINIT
+FunctionEnd
+
+; The stuff to install
+Section "ioquake3 (required)"
+
+  SectionIn RO
+
+  ; Set output path to the installation directory.
+  SetOutPath $INSTDIR
+
+  ; Put file there
+  File "../../build/release-mingw32-x86/ioq3ded.x86.exe"
+  File "../../build/release-mingw32-x86/ioquake3.x86.exe"
+  File "../../COPYING.txt"
+  File "../../README.txt"
+  File "../../id-readme.txt"
+  File "../../voip-readme.txt"
+
+  SetOutPath "$INSTDIR\baseq3"
+  File "../../build/release-mingw32-x86/baseq3/cgamex86.dll"
+  File "../../build/release-mingw32-x86/baseq3/qagamex86.dll"
+  File "../../build/release-mingw32-x86/baseq3/uix86.dll"
+  SetOutPath "$INSTDIR\missionpack"
+  File "../../build/release-mingw32-x86/missionpack/cgamex86.dll"
+  File "../../build/release-mingw32-x86/missionpack/qagamex86.dll"
+  File "../../build/release-mingw32-x86/missionpack/uix86.dll"
+
+  ; Write the installation path into the registry
+  WriteRegStr SHCTX "Software\ioquake3" ${MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME} "$INSTDIR"
+  WriteRegStr SHCTX "Software\ioquake3" ${MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME} "$MultiUser.InstallMode"
+
+  ; Write the uninstall keys for Windows
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\ioquake3" "DisplayName" "ioquake3"
+  WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\ioquake3" "UninstallString" '"$INSTDIR\uninstall.exe"'
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\ioquake3" "NoModify" 1
+  WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\ioquake3" "NoRepair" 1
+  WriteUninstaller "uninstall.exe"
+
+SectionEnd
+
+; Optional section (can be disabled by the user)
+Section "Start Menu Shortcuts"
+
+  CreateDirectory "$SMPROGRAMS\ioquake3"
+  CreateShortCut "$SMPROGRAMS\ioquake3\Uninstall.lnk" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0
+  CreateShortCut "$SMPROGRAMS\ioquake3\ioquake3.lnk" "$INSTDIR\ioquake3.x86.exe" "" "$INSTDIR\ioquake3.x86.exe" 0
+
+SectionEnd
+
+Section "SDL.dll"
+
+  SetOutPath $INSTDIR
+
+  File "SDL.dll"
+
+SectionEnd
+
+Section "libcurl"
+
+  SetOutPath $INSTDIR
+
+  File "libcurl-4.dll"
+
+SectionEnd
+
+Section "OpenAL-Soft library"
+
+  SetOutPath $INSTDIR
+
+  File "OpenAL32.dll"
+
+SectionEnd
+
+;--------------------------------
+
+; Uninstaller
+
+Section "Uninstall"
+
+  ; Remove registry keys
+  DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\ioquake3"
+  DeleteRegKey SHCTX "Software\ioquake3"
+
+  ; Remove files and uninstaller
+  Delete $INSTDIR\baseq3\cgamex86.dll
+  Delete $INSTDIR\baseq3\qagamex86.dll
+  Delete $INSTDIR\baseq3\uix86.dll
+  Delete $INSTDIR\missionpack\cgamex86.dll
+  Delete $INSTDIR\missionpack\qagamex86.dll
+  Delete $INSTDIR\missionpack\uix86.dll
+  Delete $INSTDIR\ioquake3.x86.exe
+  Delete $INSTDIR\ioq3ded.x86.exe
+
+  Delete $INSTDIR\COPYING.txt
+  Delete $INSTDIR\README.txt
+  Delete $INSTDIR\id-readme.txt
+  Delete $INSTDIR\voip-readme.txt
+
+  Delete $INSTDIR\SDL.dll
+
+  Delete $INSTDIR\libcurl-4.dll
+
+  Delete $INSTDIR\OpenAL32.dll
+
+  Delete $INSTDIR\uninstall.exe
+
+  ; Remove shortcuts, if any
+  Delete "$SMPROGRAMS\ioquake3\Uninstall.lnk"
+  Delete "$SMPROGRAMS\ioquake3\ioquake3.lnk"
+
+  ; Remove directories used
+  RMDir "$SMPROGRAMS\ioquake3"
+  RMDir "$INSTDIR\baseq3"
+  RMDir "$INSTDIR\missionpack"
+  RMDir "$INSTDIR"
+
+SectionEnd