added clahef_rook.f and zlahef_rook.f

4 files changed, 2270 insertions, 20 deletions

diff --git a/SRC/CMakeLists.txt b/SRC/CMakeLists.txt
index e0935de2..0c9bd5fc 100644
--- a/SRC/CMakeLists.txt
+++ b/SRC/CMakeLists.txt
@@ -113,7 +113,7 @@ set(SLASRC
    slaqtr.f slar1v.f slar2v.f ilaslr.f ilaslc.f 
    slarf.f  slarfb.f slarfg.f slarfgp.f slarft.f slarfx.f slargv.f 
    slarrv.f slartv.f 
-   slarz.f  slarzb.f slarzt.f slaswp.f slasy2.f slasyf.f 
+   slarz.f  slarzb.f slarzt.f slaswp.f slasy2.f slasyf.f slasyf_rook.f 
    slatbs.f slatdf.f slatps.f slatrd.f slatrs.f slatrz.f slatzm.f 
    slauu2.f slauum.f sopgtr.f sopmtr.f sorg2l.f sorg2r.f 
    sorgbr.f sorghr.f sorgl2.f sorglq.f sorgql.f sorgqr.f sorgr2.f 
@@ -134,7 +134,7 @@ set(SLASRC
    ssygst.f ssygv.f  ssygvd.f ssygvx.f ssyrfs.f ssysv.f  ssysvx.f 
    ssytd2.f ssytf2.f ssytrd.f ssytrf.f ssytri.f ssytri2.f ssytri2x.f
    ssyswapr.f ssytrs.f ssytrs2.f ssyconv.f 
-   ssytf2_rook.f slasyf_rook.f ssytrf_rook.f ssytrs_rook.f
+   ssytf2_rook.f ssytrf_rook.f ssytrs_rook.f
    ssytri_rook.f ssycon_rook.f ssysv_rook.f
    stbcon.f 
    stbrfs.f stbtrs.f stgevc.f stgex2.f stgexc.f stgsen.f 
@@ -187,7 +187,7 @@ set(CLASRC
    clacgv.f clacon.f clacn2.f clacp2.f clacpy.f clacrm.f clacrt.f cladiv.f 
    claed0.f claed7.f claed8.f 
    claein.f claesy.f claev2.f clags2.f clagtm.f 
-   clahef.f clahqr.f 
+   clahef.f clahef_rook.f clahqr.f 
    clahrd.f clahr2.f claic1.f clals0.f clalsa.f clalsd.f clangb.f clange.f clangt.f 
    clanhb.f clanhe.f 
    clanhp.f clanhs.f clanht.f clansb.f clansp.f clansy.f clantb.f 
@@ -198,7 +198,7 @@ set(CLASRC
    clarf.f  clarfb.f clarfg.f clarfgp.f clarft.f 
    clarfx.f clargv.f clarnv.f clarrv.f clartg.f clartv.f 
    clarz.f  clarzb.f clarzt.f clascl.f claset.f clasr.f  classq.f 
-   claswp.f clasyf.f clatbs.f clatdf.f clatps.f clatrd.f clatrs.f clatrz.f 
+   claswp.f clasyf.f clasyf_rook.f clatbs.f clatdf.f clatps.f clatrd.f clatrs.f clatrz.f 
    clatzm.f clauu2.f clauum.f cpbcon.f cpbequ.f cpbrfs.f cpbstf.f cpbsv.f  
    cpbsvx.f cpbtf2.f cpbtrf.f cpbtrs.f cpocon.f cpoequ.f cporfs.f 
    cposv.f  cposvx.f cpotf2.f cpotrf.f cpotri.f cpotrs.f cpstrf.f cpstf2.f 
@@ -210,7 +210,7 @@ set(CLASRC
    csyr.f   csyrfs.f csysv.f  csysvx.f csytf2.f csytrf.f csytri.f 
    csytri2.f csytri2x.f csyswapr.f
    csytrs.f csytrs2.f csyconv.f 
-   csytf2_rook.f clasyf_rook.f csytrf_rook.f csytrs_rook.f
+   csytf2_rook.f csytrf_rook.f csytrs_rook.f
    csytri_rook.f csycon_rook.f csysv_rook.f
    ctbcon.f ctbrfs.f ctbtrs.f ctgevc.f ctgex2.f 
    ctgexc.f ctgsen.f ctgsja.f ctgsna.f ctgsy2.f ctgsyl.f ctpcon.f 
@@ -267,7 +267,7 @@ set(DLASRC
    dlaqtr.f dlar1v.f dlar2v.f iladlr.f iladlc.f 
    dlarf.f  dlarfb.f dlarfg.f dlarfgp.f dlarft.f dlarfx.f dlargv.f 
    dlarrv.f dlartv.f 
-   dlarz.f  dlarzb.f dlarzt.f dlaswp.f dlasy2.f dlasyf.f 
+   dlarz.f  dlarzb.f dlarzt.f dlaswp.f dlasy2.f dlasyf.f dlasyf_rook.f 
    dlatbs.f dlatdf.f dlatps.f dlatrd.f dlatrs.f dlatrz.f dlatzm.f dlauu2.f 
    dlauum.f dopgtr.f dopmtr.f dorg2l.f dorg2r.f 
    dorgbr.f dorghr.f dorgl2.f dorglq.f dorgql.f dorgqr.f dorgr2.f 
@@ -289,7 +289,7 @@ set(DLASRC
    dsysv.f  dsysvx.f 
    dsytd2.f dsytf2.f dsytrd.f dsytrf.f dsytri.f dsytrs.f dsytrs2.f 
    dsytri2.f dsytri2x.f dsyswapr.f dsyconv.f
-   dsytf2_rook.f dlasyf_rook.f dsytrf_rook.f dsytrs_rook.f
+   dsytf2_rook.f dsytrf_rook.f dsytrs_rook.f
    dsytri_rook.f dsycon_rook.f dsysv_rook.f
    dtbcon.f 
    dtbrfs.f dtbtrs.f dtgevc.f dtgex2.f dtgexc.f dtgsen.f 
@@ -340,7 +340,7 @@ set(ZLASRC
    zlacgv.f zlacon.f zlacn2.f zlacp2.f zlacpy.f zlacrm.f zlacrt.f zladiv.f 
    zlaed0.f zlaed7.f zlaed8.f 
    zlaein.f zlaesy.f zlaev2.f zlags2.f zlagtm.f 
-   zlahef.f zlahqr.f 
+   zlahef.f zlahef_rook.f zlahqr.f 
    zlahrd.f zlahr2.f zlaic1.f zlals0.f zlalsa.f zlalsd.f zlangb.f zlange.f 
    zlangt.f zlanhb.f 
    zlanhe.f 
@@ -353,7 +353,7 @@ set(ZLASRC
    zlarfg.f zlarfgp.f zlarft.f
    zlarfx.f zlargv.f zlarnv.f zlarrv.f zlartg.f zlartv.f 
    zlarz.f  zlarzb.f zlarzt.f zlascl.f zlaset.f zlasr.f  
-   zlassq.f zlaswp.f zlasyf.f 
+   zlassq.f zlaswp.f zlasyf.f zlasyf_rook.f 
    zlatbs.f zlatdf.f zlatps.f zlatrd.f zlatrs.f zlatrz.f zlatzm.f zlauu2.f 
    zlauum.f zpbcon.f zpbequ.f zpbrfs.f zpbstf.f zpbsv.f  
    zpbsvx.f zpbtf2.f zpbtrf.f zpbtrs.f zpocon.f zpoequ.f zporfs.f 
@@ -366,7 +366,7 @@ set(ZLASRC
    zsyr.f   zsyrfs.f zsysv.f  zsysvx.f zsytf2.f zsytrf.f zsytri.f 
    zsytri2.f zsytri2x.f zsyswapr.f
    zsytrs.f zsytrs2.f zsyconv.f
-   zsytf2_rook.f zlasyf_rook.f zsytrf_rook.f zsytrs_rook.f
+   zsytf2_rook.f zsytrf_rook.f zsytrs_rook.f
    zsytri_rook.f zsycon_rook.f zsysv_rook.f
    ztbcon.f ztbrfs.f ztbtrs.f ztgevc.f ztgex2.f 
    ztgexc.f ztgsen.f ztgsja.f ztgsna.f ztgsy2.f ztgsyl.f ztpcon.f 
diff --git a/SRC/Makefile b/SRC/Makefile
index 0679f3de..e5729cdd 100644
--- a/SRC/Makefile
+++ b/SRC/Makefile
@@ -118,7 +118,7 @@ SLASRC = \
    slaqtr.o slar1v.o slar2v.o ilaslr.o ilaslc.o \
    slarf.o  slarfb.o slarfg.o slarfgp.o slarft.o slarfx.o slargv.o \
    slarrv.o slartv.o  \
-   slarz.o  slarzb.o slarzt.o slaswp.o slasy2.o slasyf.o \
+   slarz.o  slarzb.o slarzt.o slaswp.o slasy2.o slasyf.o slasyf_rook.o \
    slatbs.o slatdf.o slatps.o slatrd.o slatrs.o slatrz.o slatzm.o \
    slauu2.o slauum.o sopgtr.o sopmtr.o sorg2l.o sorg2r.o \
    sorgbr.o sorghr.o sorgl2.o sorglq.o sorgql.o sorgqr.o sorgr2.o \
@@ -140,7 +140,7 @@ SLASRC = \
    ssygst.o ssygv.o  ssygvd.o ssygvx.o ssyrfs.o ssysv.o  ssysvx.o \
    ssytd2.o ssytf2.o ssytrd.o ssytrf.o ssytri.o ssytri2.o ssytri2x.o \
    ssyswapr.o ssytrs.o ssytrs2.o ssyconv.o \
-   ssytf2_rook.o slasyf_rook.o ssytrf_rook.o ssytrs_rook.o \
+   ssytf2_rook.o ssytrf_rook.o ssytrs_rook.o \
    ssytri_rook.o ssycon_rook.o ssysv_rook.o \
    stbcon.o \
    stbrfs.o stbtrs.o stgevc.o stgex2.o stgexc.o stgsen.o \
@@ -194,7 +194,7 @@ CLASRC = \
    clacgv.o clacon.o clacn2.o clacp2.o clacpy.o clacrm.o clacrt.o cladiv.o \
    claed0.o claed7.o claed8.o \
    claein.o claesy.o claev2.o clags2.o clagtm.o \
-   clahef.o clahqr.o \
+   clahef.o clahef_rook.o clahqr.o \
    clahrd.o clahr2.o claic1.o clals0.o clalsa.o clalsd.o clangb.o clange.o clangt.o \
    clanhb.o clanhe.o \
    clanhp.o clanhs.o clanht.o clansb.o clansp.o clansy.o clantb.o \
@@ -205,7 +205,7 @@ CLASRC = \
    clarf.o  clarfb.o clarfg.o clarft.o clarfgp.o \
    clarfx.o clargv.o clarnv.o clarrv.o clartg.o clartv.o \
    clarz.o  clarzb.o clarzt.o clascl.o claset.o clasr.o  classq.o \
-   claswp.o clasyf.o clatbs.o clatdf.o clatps.o clatrd.o clatrs.o clatrz.o \
+   claswp.o clasyf.o clasyf_rook.o clatbs.o clatdf.o clatps.o clatrd.o clatrs.o clatrz.o \
    clatzm.o clauu2.o clauum.o cpbcon.o cpbequ.o cpbrfs.o cpbstf.o cpbsv.o  \
    cpbsvx.o cpbtf2.o cpbtrf.o cpbtrs.o cpocon.o cpoequ.o cporfs.o \
    cposv.o  cposvx.o cpotf2.o cpotri.o cpstrf.o cpstf2.o \
@@ -217,7 +217,7 @@ CLASRC = \
    csycon.o csymv.o \
    csyr.o csyrfs.o csysv.o  csysvx.o csytf2.o csytrf.o csytri.o csytri2.o csytri2x.o \
    csyswapr.o csytrs.o csytrs2.o csyconv.o \
-   csytf2_rook.o clasyf_rook.o csytrf_rook.o csytrs_rook.o \
+   csytf2_rook.o csytrf_rook.o csytrs_rook.o \
    csytri_rook.o csycon_rook.o csysv_rook.o \
    ctbcon.o ctbrfs.o ctbtrs.o ctgevc.o ctgex2.o \
    ctgexc.o ctgsen.o ctgsja.o ctgsna.o ctgsy2.o ctgsyl.o ctpcon.o \
@@ -276,7 +276,7 @@ DLASRC = \
    dlaqtr.o dlar1v.o dlar2v.o iladlr.o iladlc.o \
    dlarf.o  dlarfb.o dlarfg.o dlarfgp.o dlarft.o dlarfx.o \
    dlargv.o dlarrv.o dlartv.o  \
-   dlarz.o  dlarzb.o dlarzt.o dlaswp.o dlasy2.o dlasyf.o \
+   dlarz.o  dlarzb.o dlarzt.o dlaswp.o dlasy2.o dlasyf.o dlasyf_rook.o \
    dlatbs.o dlatdf.o dlatps.o dlatrd.o dlatrs.o dlatrz.o dlatzm.o dlauu2.o \
    dlauum.o dopgtr.o dopmtr.o dorg2l.o dorg2r.o \
    dorgbr.o dorghr.o dorgl2.o dorglq.o dorgql.o dorgqr.o dorgr2.o \
@@ -299,7 +299,7 @@ DLASRC = \
    dsysv.o  dsysvx.o \
    dsytd2.o dsytf2.o dsytrd.o dsytrf.o dsytri.o dsytri2.o dsytri2x.o \
    dsyswapr.o dsytrs.o dsytrs2.o dsyconv.o \
-   dsytf2_rook.o dlasyf_rook.o dsytrf_rook.o dsytrs_rook.o \
+   dsytf2_rook.o dsytrf_rook.o dsytrs_rook.o \
    dsytri_rook.o dsycon_rook.o dsysv_rook.o \
    dtbcon.o dtbrfs.o dtbtrs.o dtgevc.o dtgex2.o dtgexc.o dtgsen.o \
    dtgsja.o dtgsna.o dtgsy2.o dtgsyl.o dtpcon.o dtprfs.o dtptri.o \
@@ -351,7 +351,7 @@ ZLASRC = \
    zlacgv.o zlacon.o zlacn2.o zlacp2.o zlacpy.o zlacrm.o zlacrt.o zladiv.o \
    zlaed0.o zlaed7.o zlaed8.o \
    zlaein.o zlaesy.o zlaev2.o zlags2.o zlagtm.o \
-   zlahef.o zlahqr.o \
+   zlahef.o zlahef_rook.o zlahqr.o \
    zlahrd.o zlahr2.o zlaic1.o zlals0.o zlalsa.o zlalsd.o zlangb.o zlange.o \
    zlangt.o zlanhb.o \
    zlanhe.o \
@@ -364,7 +364,7 @@ ZLASRC = \
    zlarfg.o zlarft.o zlarfgp.o \
    zlarfx.o zlargv.o zlarnv.o zlarrv.o zlartg.o zlartv.o \
    zlarz.o  zlarzb.o zlarzt.o zlascl.o zlaset.o zlasr.o  \
-   zlassq.o zlaswp.o zlasyf.o \
+   zlassq.o zlaswp.o zlasyf.o zlasyf_rook.o \
    zlatbs.o zlatdf.o zlatps.o zlatrd.o zlatrs.o zlatrz.o zlatzm.o zlauu2.o \
    zlauum.o zpbcon.o zpbequ.o zpbrfs.o zpbstf.o zpbsv.o  \
    zpbsvx.o zpbtf2.o zpbtrf.o zpbtrs.o zpocon.o zpoequ.o zporfs.o \
@@ -377,7 +377,7 @@ ZLASRC = \
    zsycon.o zsymv.o \
    zsyr.o zsyrfs.o zsysv.o  zsysvx.o zsytf2.o zsytrf.o zsytri.o zsytri2.o zsytri2x.o \
    zsyswapr.o zsytrs.o zsytrs2.o zsyconv.o \
-   zsytf2_rook.o zlasyf_rook.o zsytrf_rook.o zsytrs_rook.o \
+   zsytf2_rook.o zsytrf_rook.o zsytrs_rook.o \
    zsytri_rook.o zsycon_rook.o zsysv_rook.o \
    ztbcon.o ztbrfs.o ztbtrs.o ztgevc.o ztgex2.o \
    ztgexc.o ztgsen.o ztgsja.o ztgsna.o ztgsy2.o ztgsyl.o ztpcon.o \
diff --git a/SRC/clahef_rook.f b/SRC/clahef_rook.f
new file mode 100644
index 00000000..820b56f4
--- /dev/null
+++ b/SRC/clahef_rook.f
@@ -0,0 +1,1125 @@
+* \brief \b CLAHEF_ROOK computes a partial factorization of a complex Hermitian indefinite matrix using the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
+*
+*  =========== DOCUMENTATION ===========
+*
+* Online html documentation available at
+*            http://www.netlib.org/lapack/explore-html/
+*
+*> \htmlonly
+*> Download CLAHEF_ROOK + dependencies
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clahef_rook.f">
+*> [TGZ]</a>
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clahef_rook.f">
+*> [ZIP]</a>
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clahef_rook.f">
+*> [TXT]</a>
+*> \endhtmlonly
+*
+*  Definition:
+*  ===========
+*
+*       SUBROUTINE CLAHEF_ROOK( UPLO, N, NB, KB, A, LDA, IPIV, W, LDW, INFO )
+*
+*       .. Scalar Arguments ..
+*       CHARACTER          UPLO
+*       INTEGER            INFO, KB, LDA, LDW, N, NB
+*       ..
+*       .. Array Arguments ..
+*       INTEGER            IPIV( * )
+*       COMPLEX            A( LDA, * ), W( LDW, * )
+*       ..
+*
+*
+*> \par Purpose:
+*  =============
+*>
+*> \verbatim
+*>
+*> CLAHEF_ROOK computes a partial factorization of a complex Hermitian
+*> matrix A using the bounded Bunch-Kaufman ("rook") diagonal pivoting
+*> method. The partial factorization has the form:
+*>
+*> A  =  ( I  U12 ) ( A11  0  ) (  I      0     )  if UPLO = 'U', or:
+*>       ( 0  U22 ) (  0   D  ) ( U12**H U22**H )
+*>
+*> A  =  ( L11  0 ) (  D   0  ) ( L11**H L21**H )  if UPLO = 'L'
+*>       ( L21  I ) (  0  A22 ) (  0      I     )
+*>
+*> where the order of D is at most NB. The actual order is returned in
+*> the argument KB, and is either NB or NB-1, or N if N <= NB.
+*> Note that U**H denotes the conjugate transpose of U.
+*>
+*> CLAHEF_ROOK is an auxiliary routine called by CHETRF_ROOK. It uses
+*> blocked code (calling Level 3 BLAS) to update the submatrix
+*> A11 (if UPLO = 'U') or A22 (if UPLO = 'L').
+*> \endverbatim
+*
+*  Arguments:
+*  ==========
+*
+*> \param[in] UPLO
+*> \verbatim
+*>          UPLO is CHARACTER*1
+*>          Specifies whether the upper or lower triangular part of the
+*>          Hermitian matrix A is stored:
+*>          = 'U':  Upper triangular
+*>          = 'L':  Lower triangular
+*> \endverbatim
+*>
+*> \param[in] N
+*> \verbatim
+*>          N is INTEGER
+*>          The order of the matrix A.  N >= 0.
+*> \endverbatim
+*>
+*> \param[in] NB
+*> \verbatim
+*>          NB is INTEGER
+*>          The maximum number of columns of the matrix A that should be
+*>          factored.  NB should be at least 2 to allow for 2-by-2 pivot
+*>          blocks.
+*> \endverbatim
+*>
+*> \param[out] KB
+*> \verbatim
+*>          KB is INTEGER
+*>          The number of columns of A that were actually factored.
+*>          KB is either NB-1 or NB, or N if N <= NB.
+*> \endverbatim
+*>
+*> \param[in,out] A
+*> \verbatim
+*>          A is COMPLEX array, dimension (LDA,N)
+*>          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
+*>          n-by-n upper triangular part of A contains the upper
+*>          triangular part of the matrix A, and the strictly lower
+*>          triangular part of A is not referenced.  If UPLO = 'L', the
+*>          leading n-by-n lower triangular part of A contains the lower
+*>          triangular part of the matrix A, and the strictly upper
+*>          triangular part of A is not referenced.
+*>          On exit, A contains details of the partial factorization.
+*> \endverbatim
+*>
+*> \param[in] LDA
+*> \verbatim
+*>          LDA is INTEGER
+*>          The leading dimension of the array A.  LDA >= max(1,N).
+*> \endverbatim
+*>
+*> \param[out] IPIV
+*> \verbatim
+*>          IPIV is INTEGER array, dimension (N)
+*>          Details of the interchanges and the block structure of D.
+*>
+*>          If UPLO = 'U':
+*>             Only the last KB elements of IPIV are set.
+*>
+*>             If IPIV(k) > 0, then rows and columns k and IPIV(k) were
+*>             interchanged and D(k,k) is a 1-by-1 diagonal block.
+*>
+*>             If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and
+*>             columns k and -IPIV(k) were interchanged and rows and
+*>             columns k-1 and -IPIV(k-1) were inerchaged,
+*>             D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
+*>
+*>          If UPLO = 'L':
+*>             Only the first KB elements of IPIV are set.
+*>
+*>             If IPIV(k) > 0, then rows and columns k and IPIV(k)
+*>             were interchanged and D(k,k) is a 1-by-1 diagonal block.
+*>
+*>             If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and
+*>             columns k and -IPIV(k) were interchanged and rows and
+*>             columns k+1 and -IPIV(k+1) were inerchaged,
+*>             D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
+*> \endverbatim
+*>
+*> \param[out] W
+*> \verbatim
+*>          W is COMPLEX array, dimension (LDW,NB)
+*> \endverbatim
+*>
+*> \param[in] LDW
+*> \verbatim
+*>          LDW is INTEGER
+*>          The leading dimension of the array W.  LDW >= max(1,N).
+*> \endverbatim
+*>
+*> \param[out] INFO
+*> \verbatim
+*>          INFO is INTEGER
+*>          = 0: successful exit
+*>          > 0: if INFO = k, D(k,k) is exactly zero.  The factorization
+*>               has been completed, but the block diagonal matrix D is
+*>               exactly singular.
+*> \endverbatim
+*
+*  Authors:
+*  ========
+*
+*> \author Univ. of Tennessee
+*> \author Univ. of California Berkeley
+*> \author Univ. of Colorado Denver
+*> \author NAG Ltd.
+*
+*> \date November 2012
+*
+*> \ingroup complexHEcomputational
+*
+*> \par Contributors:
+*  ==================
+*>
+*> \verbatim
+*>
+*>  November 2012,  Igor Kozachenko,
+*>                  Computer Science Division,
+*>                  University of California, Berkeley
+*>
+*>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
+*>                  School of Mathematics,
+*>                  University of Manchester
+*>
+*> \endverbatim
+*
+*  =====================================================================
+      SUBROUTINE CLAHEF_ROOK( UPLO, N, NB, KB, A, LDA, IPIV, W, LDW,
+     $                        INFO )
+*
+*  -- LAPACK computational routine (version 3.4.2) --
+*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
+*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
+*     September 2012
+*
+*     .. Scalar Arguments ..
+      CHARACTER          UPLO
+      INTEGER            INFO, KB, LDA, LDW, N, NB
+*     ..
+*     .. Array Arguments ..
+      INTEGER            IPIV( * )
+      COMPLEX            A( LDA, * ), W( LDW, * )
+*     ..
+*
+*  =====================================================================
+*
+*     .. Parameters ..
+      REAL               ZERO, ONE
+      PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
+      COMPLEX            CONE
+      PARAMETER          ( CONE = ( 1.0D+0, 0.0D+0 ) )
+      REAL               EIGHT, SEVTEN
+      PARAMETER          ( EIGHT = 8.0D+0, SEVTEN = 17.0D+0 )
+*     ..
+*     .. Local Scalars ..
+      LOGICAL            DONE
+      INTEGER            IMAX, ITEMP, II, J, JB, JJ, JMAX, JP1, JP2, K,
+     $                   KK, KKW, KP, KSTEP, KW, P
+      REAL               ABSAKK, ALPHA, COLMAX, STEMP, R1, ROWMAX, T,
+     $                   SFMIN
+      COMPLEX            D11, D21, D22, Z
+*     ..
+*     .. External Functions ..
+      LOGICAL            LSAME
+      INTEGER            ICAMAX
+      REAL               SLAMCH
+      EXTERNAL           LSAME, ICAMAX, SLAMCH
+*     ..
+*     .. External Subroutines ..
+      EXTERNAL           CCOPY, CSSCAL, CGEMM, CGEMV, CLACGV, CSWAP
+*     ..
+*     .. Intrinsic Functions ..
+      INTRINSIC          ABS, CONJG, IMAG, MAX, MIN, REAL, SQRT
+*     ..
+*     .. Statement Functions ..
+      REAL               CABS1
+*     ..
+*     .. Statement Function definitions ..
+      CABS1( Z ) = ABS( REAL( Z ) ) + ABS( IMAG( Z ) )
+*     ..
+*     .. Executable Statements ..
+*
+      INFO = 0
+*
+*     Initialize ALPHA for use in choosing pivot block size.
+*
+      ALPHA = ( ONE+SQRT( SEVTEN ) ) / EIGHT
+*
+*     Compute machine safe minimum
+*
+      SFMIN = SLAMCH( 'S' )
+*
+      IF( LSAME( UPLO, 'U' ) ) THEN
+*
+*        Factorize the trailing columns of A using the upper triangle
+*        of A and working backwards, and compute the matrix W = U12*D
+*        for use in updating A11
+*
+*        K is the main loop index, decreasing from N in steps of 1 or 2
+*
+         K = N
+   10    CONTINUE
+*
+*        KW is the column of W which corresponds to column K of A
+*
+         KW = NB + K - N
+*
+*        Exit from loop
+*
+         IF( ( K.LE.N-NB+1 .AND. NB.LT.N ) .OR. K.LT.1 )
+     $      GO TO 30
+*
+         KSTEP = 1
+         P = K
+*
+*        Copy column K of A to column KW of W and update it
+*
+         IF( K.GT.1 )
+     $      CALL CCOPY( K-1, A( 1, K ), 1, W( 1, KW ), 1 )
+         W( K, KW ) = REAL( A( K, K ) )
+         IF( K.LT.N ) THEN
+            CALL CGEMV( 'No transpose', K, N-K, -CONE, A( 1, K+1 ), LDA,
+     $                  W( K, KW+1 ), LDW, CONE, W( 1, KW ), 1 )
+            W( K, KW ) = REAL( W( K, KW ) )
+         END IF
+*
+*        Determine rows and columns to be interchanged and whether
+*        a 1-by-1 or 2-by-2 pivot block will be used
+*
+         ABSAKK = ABS( REAL( W( K, K ) ) )
+*
+*        IMAX is the row-index of the largest off-diagonal element in
+*        column K, and COLMAX is its absolute value
+*
+         IF( K.GT.1 ) THEN
+            IMAX = ICAMAX( K-1, W( 1, KW ), 1 )
+            COLMAX = CABS1( W( IMAX, KW ) )
+         ELSE
+            COLMAX = ZERO
+         END IF
+*
+         IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
+*
+*           Column K is zero: set INFO and continue
+*
+            IF( INFO.EQ.0 )
+     $         INFO = K
+            KP = K
+            IF( K.GT.1 )
+     $         CALL CCOPY( K-1, W( 1, K ), 1, A( 1, KW ), 1 )
+            A( K, K ) = REAL( A( K, K ) )
+         ELSE
+*
+*           ============================================================
+*
+*           Test for interchange
+*
+*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
+*           (used to handle NaN and Inf)
+*
+            IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
+*
+*              no interchange, use 1-by-1 pivot block
+*
+               KP = K
+*
+            ELSE
+*
+               DONE = .FALSE.
+*
+*              Loop until pivot found
+*
+   12          CONTINUE
+*
+*                 Begin pivot search loop body
+*
+*
+*                 Copy column IMAX to column KW-1 of W and update it
+*
+                  IF( IMAX.GT.1 )
+     $               CALL CCOPY( IMAX-1, A( 1, IMAX ), 1, W( 1, KW-1 ),
+     $                           1 )
+                  W( IMAX, KW-1 ) = REAL( A( IMAX, IMAX ) )
+                  CALL CCOPY( K-IMAX, A( IMAX, IMAX+1 ), LDA,
+     $                        W( IMAX+1, KW-1 ), 1 )
+                  CALL CLACGV( K-IMAX, W( IMAX+1, KW-1 ), 1 )
+                  IF( K.LT.N ) THEN
+                     CALL CGEMV( 'No transpose', K, N-K, -CONE,
+     $                           A( 1, K+1 ), LDA, W( IMAX, KW+1 ), LDW,
+     $                           CONE, W( 1, KW-1 ), 1 )
+                     W( IMAX, KW-1 ) = REAL( W( IMAX, KW-1 ) )
+                  END IF
+*
+*                 JMAX is the column-index of the largest off-diagonal
+*                 element in row IMAX, and ROWMAX is its absolute value.
+*                 Determine both ROWMAX and JMAX.
+*
+                  IF( IMAX.NE.K ) THEN
+                     JMAX = IMAX + ICAMAX( K-IMAX, W( IMAX+1, KW-1 ),
+     $                                     1 )
+                     ROWMAX = CABS1( W( JMAX, KW-1 ) )
+                  ELSE
+                     ROWMAX = ZERO
+                  END IF
+*
+                  IF( IMAX.GT.1 ) THEN
+                     ITEMP = ICAMAX( IMAX-1, W( 1, KW-1 ), 1 )
+                     STEMP = CABS1( W( ITEMP, KW-1 ) )
+                     IF( STEMP.GT.ROWMAX ) THEN
+                        ROWMAX = STEMP
+                        JMAX = ITEMP
+                     END IF
+                  END IF
+*
+*                 Equivalent to testing for
+*                 ABS( REAL( W( IMAX,KW-1 ) ) ).GE.ALPHA*ROWMAX
+*                 (used to handle NaN and Inf)
+*
+                  IF( .NOT.( ABS( REAL( W( IMAX,KW-1 ) ) )
+     $                       .LT.ALPHA*ROWMAX ) ) THEN
+*
+*                    interchange rows and columns K and IMAX,
+*                    use 1-by-1 pivot block
+*
+                     KP = IMAX
+*
+*                    copy column KW-1 of W to column KW of W
+*
+                     CALL CCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
+*
+                     DONE = .TRUE.
+*
+*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
+*                 (used to handle NaN and Inf)
+*
+                  ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
+     $            THEN
+*
+*                    interchange rows and columns K-1 and IMAX,
+*                    use 2-by-2 pivot block
+*
+                     KP = IMAX
+                     KSTEP = 2
+                     DONE = .TRUE.
+                  ELSE
+*
+*                    Pivot not found: set params and repeat
+*
+                     P = IMAX
+                     COLMAX = ROWMAX
+                     IMAX = JMAX
+*
+*                    Copy updated JMAXth (next IMAXth) column to Kth of W
+*
+                     CALL CCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
+*
+                  END IF
+*
+*                 End pivot search loop body
+*
+               IF( .NOT.DONE ) GOTO 12
+*
+            END IF
+*
+*           ============================================================
+*
+*           KK is the column of A where pivoting step stopped
+*
+            KK = K - KSTEP + 1
+*
+*           KKW is the column of W which corresponds to column KK of A
+*
+            KKW = NB + KK - N
+*
+*           Interchange rows and columns P and K.
+*           Updated column P is already stored in column KW of W.
+*
+            IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
+*
+*              Copy non-updated column KK+1 to column P of submatrix A
+*              at step K. No need to copy element into columns
+*              K and K-1 of A for 2-by-2 pivot, since these columns
+*              will be later overwritten.
+*
+               A( P, P ) = REAL( A( K, K ) )
+               CALL CCOPY( K-1-P, A( P+1, K ), 1, A( P, P+1 ),
+     $                     LDA )
+               CALL CLACGV( K-1-P, A( P, P+1 ), LDA )
+               IF( P.GT.1 )
+     $            CALL CCOPY( P-1, A( 1, K ), 1, A( 1, P ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K and K-1 of A for 2-by-2 pivot will be
+*              later overwritten). Interchange rows KK and KP
+*              in last KW to NB columns of W.
+*
+               IF( K.LT.N )
+     $            CALL CSWAP( N-K, A( K, K+1 ), LDA, A( P, K+1 ),
+     $                        LDA )
+               CALL CSWAP( N-K+1, W( K, KW ), LDW, W( P, KW ),
+     $                     LDW )
+            END IF
+*
+*           Interchange rows and columns KP and KK.
+*           Updated column KP is already stored in column KKW of W.
+*
+            IF( KP.NE.KK ) THEN
+*
+*              Copy non-updated column KK to column KP of submatrix A
+*              at step K. No need to copy element into column K
+*              (or K and K-1 for 2-by-2 pivot) of A, since these columns
+*              will be later overwritten.
+*
+               A( KP, KP ) = REAL( A( KK, KK ) )
+               CALL CCOPY( KK-1-KP, A( KP+1, KK ), 1, A( KP, KP+1 ),
+     $                     LDA )
+               CALL CLACGV( KK-1-KP, A( KP, KP+1 ), LDA )
+               IF( KP.GT.1 )
+     $            CALL CCOPY( KP-1, A( 1, KK ), 1, A( 1, KP ), 1 )
+*
+*              Interchange rows KK and KP in last K+1 to N columns of A
+*              (columns K (or K and K-1 for 2-by-2 pivot) of A will be
+*              later overwritten). Interchange rows KK and KP
+*              in last KKW to NB columns of W.
+*
+               IF( K.LT.N )
+     $            CALL CSWAP( N-K, A( KK, K+1 ), LDA, A( KP, K+1 ),
+     $                        LDA )
+               CALL CSWAP( N-KK+1, W( KK, KKW ), LDW, W( KP, KKW ),
+     $                     LDW )
+            END IF
+*
+            IF( KSTEP.EQ.1 ) THEN
+*
+*              1-by-1 pivot block D(k): column kw of W now holds
+*
+*              W(kw) = U(k)*D(k),
+*
+*              where U(k) is the k-th column of U
+*
+*              (1) Store subdiag. elements of column U(k)
+*              and 1-by-1 block D(k) in column k of A.
+*              (NOTE: Diagonal element U(k,k) is a UNIT element
+*              and not stored)
+*                 A(k,k) := D(k,k) = W(k,kw)
+*                 A(1:k-1,k) := U(1:k-1,k) = W(1:k-1,kw)/D(k,k)
+*
+*              (NOTE: No need to use for Hermitian matrix
+*              A( K, K ) = REAL( W( K, K) ) to separately copy diagonal
+*              element D(k,k) from W (potentially saves only one load))
+               CALL CCOPY( K, W( 1, KW ), 1, A( 1, K ), 1 )
+               IF( K.GT.1 ) THEN
+*
+*                 Handle division by a small number
+*
+                  T = REAL( A( K, K ) )
+                  IF( ABS( T ).GE.SFMIN ) THEN
+                     R1 = ONE / T
+                     CALL CSSCAL( K-1, R1, A( 1, K ), 1 )
+                  ELSE
+*                    (NOTE: No need to check if T=D(k,k) is NOT ZERO,
+*                    since that was ensured earlier in pivot search)
+                     DO 14 II = 1, K-1
+                        A( II, K ) = A( II, K ) / T
+   14                CONTINUE
+                  END IF
+*
+*                 (2) Conjugate column W(kw)
+*
+                  CALL CLACGV( K-1, W( 1, KW ), 1 )
+               END IF
+*
+            ELSE
+*
+*              2-by-2 pivot block D(k): columns kw and kw-1 of W now hold
+*
+*              ( W(kw-1) W(kw) ) = ( U(k-1) U(k) )*D(k)
+*
+*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
+*              of U
+*
+*              (1) Store U(1:k-2,k-1) and U(1:k-2,k) and 2-by-2
+*              block D(k-1:k,k-1:k) in columns k-1 and k of A.
+*              (NOTE: 2-by-2 diagonal block U(k-1:k,k-1:k) is a UNIT
+*              block and not stored)
+*                 A(k-1:k,k-1:k) := D(k-1:k,k-1:k) = W(k-1:k,kw-1:kw)
+*                 A(1:k-2,k-1:k) := U(1:k-2,k:k-1:k) =
+*                 = W(1:k-2,kw-1:kw) * ( D(k-1:k,k-1:k)**(-1) )
+*
+               IF( K.GT.2 ) THEN
+*
+*                 Compose the columns of the inverse of 2-by-2 pivot
+*                 block D in the following way to reduce the number
+*                 of FLOPS when we myltiply panel ( W(kw-1) W(kw) ) by
+*                 this inverse
+*
+*                 D**(-1) = ( d11 cj(d21) )**(-1) =
+*                           ( d21    d22 )
+*
+*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
+*                                          ( (-d21) (     d11 ) )
+*
+*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
+*
+*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
+*                     (     (      -1 )           ( d11/conj(d21) ) )
+*
+*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
+*
+*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                     (     (  -1 )           ( D22 ) )
+*
+*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                                      (     (  -1 )           ( D22 ) )
+*
+*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
+*                   (               (  -1 )         ( D22 ) )
+*
+*                 Handle division by a small number. (NOTE: order of
+*                 operations is important)
+*
+*                 = ( T*(( D11 )/conj(D21)) T*((  -1 )/D21 ) )
+*                   (   ((  -1 )          )   (( D22 )     ) )
+*
+                  D21 = W( K-1, KW )
+                  D11 = W( K, KW ) / CONJG( D21 )
+                  D22 = W( K-1, KW-1 ) / D21
+                  T = ONE / ( REAL( D11*D22 )-ONE )
+*
+*                 Update elements in columns A(k-1) and A(k) as
+*                 dot products of rows of ( W(kw-1) W(kw) ) and columns
+*                 of D**(-1)
+*
+                  DO 20 J = 1, K - 2
+                     A( J, K-1 ) = T*( ( D11*W( J, KW-1 )-W( J, KW ) ) /
+     $                             D21 )
+                     A( J, K ) = T*( ( D22*W( J, KW )-W( J, KW-1 ) ) /
+     $                           CONJG( D21 ) )
+   20             CONTINUE
+               END IF
+*
+*              Copy D(k) to A
+*
+               A( K-1, K-1 ) = W( K-1, KW-1 )
+               A( K-1, K ) = W( K-1, KW )
+               A( K, K ) = W( K, KW )
+*
+*              (2) Conjugate columns W(kw) and W(kw-1)
+*
+               CALL CLACGV( K-1, W( 1, KW ), 1 )
+               CALL CLACGV( K-2, W( 1, KW-1 ), 1 )
+*
+            END IF
+*
+         END IF
+*
+*        Store details of the interchanges in IPIV
+*
+         IF( KSTEP.EQ.1 ) THEN
+            IPIV( K ) = KP
+         ELSE
+            IPIV( K ) = -P
+            IPIV( K-1 ) = -KP
+         END IF
+*
+*        Decrease K and return to the start of the main loop
+*
+         K = K - KSTEP
+         GO TO 10
+*
+   30    CONTINUE
+*
+*        Update the upper triangle of A11 (= A(1:k,1:k)) as
+*
+*        A11 := A11 - U12*D*U12**H = A11 - U12*W**H
+*
+*        computing blocks of NB columns at a time (note that conjg(W) is
+*        actually stored)
+*
+         DO 50 J = ( ( K-1 ) / NB )*NB + 1, 1, -NB
+            JB = MIN( NB, K-J+1 )
+*
+*           Update the upper triangle of the diagonal block
+*
+            DO 40 JJ = J, J + JB - 1
+               A( JJ, JJ ) = REAL( A( JJ, JJ ) )
+               CALL CGEMV( 'No transpose', JJ-J+1, N-K, -CONE,
+     $                     A( J, K+1 ), LDA, W( JJ, KW+1 ), LDW, CONE,
+     $                     A( J, JJ ), 1 )
+               A( JJ, JJ ) = REAL( A( JJ, JJ ) )
+   40       CONTINUE
+*
+*           Update the rectangular superdiagonal block
+*
+            CALL CGEMM( 'No transpose', 'Transpose', J-1, JB, N-K,
+     $                  -CONE, A( 1, K+1 ), LDA, W( J, KW+1 ), LDW,
+     $                  CONE, A( 1, J ), LDA )
+   50    CONTINUE
+*
+*        Put U12 in standard form by partially undoing the interchanges
+*        in of rows in columns k+1:n looping backwards from k+1 to 1
+*
+         J = K + 1
+   60    CONTINUE
+*
+*           Undo the interchanges (if any) of rows J and JP2
+*           (or J and JP2, and J+1 and JP1) at each step J
+*
+            KSTEP = 1
+            JP1 = 1
+*           (Here, J is a diagonal index)
+            JJ = J
+            JP2 = IPIV( J )
+            IF( JP2.LT.0 ) THEN
+               JP2 = -JP2
+*              (Here, J is a diagonal index)
+               J = J + 1
+               JP1 = -IPIV( J )
+               KSTEP = 2
+            END IF
+*           (NOTE: Here, J is used to determine row length. Length N-J+1
+*           of the rows to swap back doesn't include diagonal element)
+            J = J + 1
+            IF( JP2.NE.JJ .AND. J.LE.N )
+     $         CALL CSWAP( N-J+1, A( JP2, J ), LDA, A( JJ, J ), LDA )
+            JJ = JJ + 1
+            IF( JP1.NE.JJ .AND. KSTEP.EQ.2 .AND. J.LE.N )
+     $         CALL CSWAP( N-J+1, A( JP1, J ), LDA, A( JJ, J ), LDA )
+         IF( J.LT.N )
+     $      GO TO 60
+*
+*        Set KB to the number of columns factorized
+*
+         KB = N - K
+*
+      ELSE
+*
+*        Factorize the leading columns of A using the lower triangle
+*        of A and working forwards, and compute the matrix W = L21*D
+*        for use in updating A22
+*
+*        K is the main loop index, increasing from 1 in steps of 1 or 2
+*
+         K = 1
+   70    CONTINUE
+*
+         IF( ( K.GE.NB .AND. NB.LT.N ) .OR. K.GT.N )
+     $      GO TO 90
+*
+         KSTEP = 1
+         P = K
+*
+*        Copy column K of A to column K of W and update column K of W
+*
+         W( K, K ) = REAL( A( K, K ) )
+         IF( K.LT.N )
+     $      CALL CCOPY( N-K, A( K+1, K ), 1, W( K+1, K ), 1 )
+         IF( K.GT.1 ) THEN
+            CALL CGEMV( 'No transpose', N-K+1, K-1, -CONE, A( K, 1 ),
+     $                  LDA, W( K, 1 ), LDW, CONE, W( K, K ), 1 )
+            W( K, K ) = REAL( W( K, K ) )
+         END IF
+*
+*        Determine rows and columns to be interchanged and whether
+*        a 1-by-1 or 2-by-2 pivot block will be used
+*
+         ABSAKK = ABS( REAL( W( K, K ) ) )
+*
+*        IMAX is the row-index of the largest off-diagonal element in
+*        column K, and COLMAX is its absolute value
+*
+         IF( K.LT.N ) THEN
+            IMAX = K + ICAMAX( N-K, W( K+1, K ), 1 )
+            COLMAX = CABS1( W( IMAX, K ) )
+         ELSE
+            COLMAX = ZERO
+         END IF
+*
+         IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
+*
+*           Column K is zero: set INFO and continue
+*
+            IF( INFO.EQ.0 )
+     $         INFO = K
+            KP = K
+            A( K, K ) = REAL( A( K, K ) )
+            IF( K.LT.N )
+     $         CALL CCOPY( N-K, W( K+1, K ), 1, A( K+1, K ), 1 )
+         ELSE
+*
+*           ============================================================
+*
+*           Test for interchange
+*
+*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
+*           (used to handle NaN and Inf)
+*
+            IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
+*
+*              no interchange, use 1-by-1 pivot block
+*
+               KP = K
+*
+            ELSE
+*
+               DONE = .FALSE.
+*
+*              Loop until pivot found
+*
+   72          CONTINUE
+*
+*                 Begin pivot search loop body
+*
+*
+*                 Copy column IMAX to column k+1 of W and update it
+*
+                  CALL CCOPY( IMAX-K, A( IMAX, K ), LDA, W( K, K+1 ), 1)
+                  CALL CLACGV( IMAX-K, W( K, K+1 ), 1 )
+                  W( IMAX, K+1 ) = REAL( A( IMAX, IMAX ) )
+                  IF( IMAX.LT.N )
+     $               CALL CCOPY( N-IMAX, A( IMAX+1, IMAX ), 1,
+     $                           W( IMAX+1, K+1 ), 1 )
+                  IF( K.GT.1 ) THEN
+                     CALL CGEMV( 'No transpose', N-K+1, K-1, -CONE,
+     $                            A( K, 1 ), LDA, W( IMAX, 1 ), LDW,
+     $                            CONE, W( K, K+1 ), 1 )
+                     W( IMAX, K+1 ) = REAL( W( IMAX, K+1 ) )
+                  END IF
+*
+*                 JMAX is the column-index of the largest off-diagonal
+*                 element in row IMAX, and ROWMAX is its absolute value.
+*                 Determine both ROWMAX and JMAX.
+*
+                  IF( IMAX.NE.K ) THEN
+                     JMAX = K - 1 + ICAMAX( IMAX-K, W( K, K+1 ), 1 )
+                     ROWMAX = CABS1( W( JMAX, K+1 ) )
+                  ELSE
+                     ROWMAX = ZERO
+                  END IF
+*
+                  IF( IMAX.LT.N ) THEN
+                     ITEMP = IMAX + ICAMAX( N-IMAX, W( IMAX+1, K+1 ), 1)
+                     STEMP = CABS1( W( ITEMP, K+1 ) )
+                     IF( STEMP.GT.ROWMAX ) THEN
+                        ROWMAX = STEMP
+                        JMAX = ITEMP
+                     END IF
+                  END IF
+*
+*                 Equivalent to testing for
+*                 ABS( REAL( W( IMAX,K+1 ) ) ).GE.ALPHA*ROWMAX
+*                 (used to handle NaN and Inf)
+*
+                  IF( .NOT.( ABS( REAL( W( IMAX,K+1 ) ) )
+     $                       .LT.ALPHA*ROWMAX ) ) THEN
+*
+*                    interchange rows and columns K and IMAX,
+*                    use 1-by-1 pivot block
+*
+                     KP = IMAX
+*
+*                    copy column K+1 of W to column K of W
+*
+                     CALL CCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
+*
+                     DONE = .TRUE.
+*
+*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
+*                 (used to handle NaN and Inf)
+*
+                  ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
+     $            THEN
+*
+*                    interchange rows and columns K+1 and IMAX,
+*                    use 2-by-2 pivot block
+*
+                     KP = IMAX
+                     KSTEP = 2
+                     DONE = .TRUE.
+                  ELSE
+*
+*                    Pivot not found: set params and repeat
+*
+                     P = IMAX
+                     COLMAX = ROWMAX
+                     IMAX = JMAX
+*
+*                    Copy updated JMAXth (next IMAXth) column to Kth of W
+*
+                     CALL CCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
+*
+                  END IF
+*
+*                 End pivot search loop body
+*
+               IF( .NOT.DONE ) GOTO 72
+*
+            END IF
+*
+*           ============================================================
+*
+*           KK is the column of A where pivoting step stopped
+*
+            KK = K + KSTEP - 1
+*
+*           Interchange rows and columns P and K (only for 2-by-2 pivot).
+*           Updated column P is already stored in column K of W.
+*
+            IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
+*
+*              Copy non-updated column KK-1 to column P of submatrix A
+*              at step K. No need to copy element into columns
+*              K and K+1 of A for 2-by-2 pivot, since these columns
+*              will be later overwritten.
+*
+               A( P, P ) = REAL( A( K, K ) )
+               CALL CCOPY( P-K-2, A( K+2, K ), 1, A( P, K+2 ), LDA )
+               CALL CLACGV( P-K-1, A( P, K+1 ), LDA )
+               IF( P.LT.N )
+     $            CALL CCOPY( N-P, A( P+1, K ), 1, A( P+1, P ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K and K+1 of A for 2-by-2 pivot will be
+*              later overwritten). Interchange rows KK and KP
+*              in first KK columns of W.
+*
+               IF( K.GT.1 )
+     $            CALL CSWAP( K-1, A( K, 1 ), LDA, A( P, 1 ), LDA )
+               CALL CSWAP( K, W( K, 1 ), LDW, W( P, 1 ), LDW )
+            END IF
+*
+*           Interchange rows and columns KP and KK.
+*           Updated column KP is already stored in column KK of W.
+*
+            IF( KP.NE.KK ) THEN
+*
+*              Copy non-updated column KK to column KP of submatrix A
+*              at step K. No need to copy element into column K
+*              (or K and K+1 for 2-by-2 pivot) of A, since these columns
+*              will be later overwritten.
+*
+               A( KP, KP ) = REAL( A( KK, KK ) )
+               CALL CCOPY( KP-KK-1, A( KK+1, KK ), 1, A( KP, KK+1 ),
+     $                     LDA )
+               CALL CLACGV( KP-KK-1, A( KP, KK+1 ), LDA )
+               IF( KP.LT.N )
+     $            CALL CCOPY( N-KP, A( KP+1, KK ), 1, A( KP+1, KP ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K (or K and K+1 for 2-by-2 pivot) of A will be
+*              later overwritten). Interchange rows KK and KP
+*              in first KK columns of W.
+*
+               IF( K.GT.1 )
+     $            CALL CSWAP( K-1, A( KK, 1 ), LDA, A( KP, 1 ), LDA )
+               CALL CSWAP( KK, W( KK, 1 ), LDW, W( KP, 1 ), LDW )
+            END IF
+*
+            IF( KSTEP.EQ.1 ) THEN
+*
+*              1-by-1 pivot block D(k): column k of W now holds
+*
+*              W(k) = L(k)*D(k),
+*
+*              where L(k) is the k-th column of L
+*
+*              (1) Store subdiag. elements of column L(k)
+*              and 1-by-1 block D(k) in column k of A.
+*              (NOTE: Diagonal element L(k,k) is a UNIT element
+*              and not stored)
+*                 A(k,k) := D(k,k) = W(k,k)
+*                 A(k+1:N,k) := L(k+1:N,k) = W(k+1:N,k)/D(k,k)
+*
+*              (NOTE: No need to use for Hermitian matrix
+*              A( K, K ) = REAL( W( K, K) ) to separately copy diagonal
+*              element D(k,k) from W (potentially saves only one load))
+               CALL CCOPY( N-K+1, W( K, K ), 1, A( K, K ), 1 )
+               IF( K.LT.N ) THEN
+*
+*                 Handle division by a small number
+*
+                  T = REAL( A( K, K ) )
+                  IF( ABS( T ).GE.SFMIN ) THEN
+                     R1 = ONE / T
+                     CALL CSSCAL( N-K, R1, A( K+1, K ), 1 )
+                  ELSE
+*                    (NOTE: No need to check if T=D(k,k) is NOT ZERO,
+*                    since that was ensured earlier in pivot search)
+                     DO 74 II = K + 1, N
+                        A( II, K ) = A( II, K ) / T
+   74                CONTINUE
+                  END IF
+*
+*                 (2) Conjugate column W(k)
+*
+                  CALL CLACGV( N-K, W( K+1, K ), 1 )
+               END IF
+*
+            ELSE
+*
+*              2-by-2 pivot block D(k): columns k and k+1 of W now hold
+*
+*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
+*
+*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
+*              of L
+*
+*              (1) Store L(k+2:N,k) and L(k+2:N,k+1) and 2-by-2
+*              block D(k:k+1,k:k+1) in columns k and k+1 of A.
+*              NOTE: 2-by-2 diagonal block L(k:k+1,k:k+1) is a UNIT
+*              block and not stored.
+*                 A(k:k+1,k:k+1) := D(k:k+1,k:k+1) = W(k:k+1,k:k+1)
+*                 A(k+2:N,k:k+1) := L(k+2:N,k:k+1) =
+*                 = W(k+2:N,k:k+1) * ( D(k:k+1,k:k+1)**(-1) )
+*
+               IF( K.LT.N-1 ) THEN
+*
+*                 Compose the columns of the inverse of 2-by-2 pivot
+*                 block D in the following way to reduce the number
+*                 of FLOPS when we myltiply panel ( W(k) W(k+1) ) by
+*                 this inverse
+*
+*                 D**(-1) = ( d11 cj(d21) )**(-1) =
+*                           ( d21    d22 )
+*
+*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
+*                                          ( (-d21) (     d11 ) )
+*
+*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
+*
+*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
+*                     (     (      -1 )           ( d11/conj(d21) ) )
+*
+*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
+*
+*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                     (     (  -1 )           ( D22 ) )
+*
+*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                                      (     (  -1 )           ( D22 ) )
+*
+*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
+*                   (               (  -1 )         ( D22 ) )
+*
+*                 Handle division by a small number. (NOTE: order of
+*                 operations is important)
+*
+*                 = ( T*(( D11 )/conj(D21)) T*((  -1 )/D21 ) )
+*                   (   ((  -1 )          )   (( D22 )     ) )
+*
+                  D21 = W( K+1, K )
+                  D11 = W( K+1, K+1 ) / D21
+                  D22 = W( K, K ) / CONJG( D21 )
+                  T = ONE / ( REAL( D11*D22 )-ONE )
+*
+*                 Update elements in columns A(k) and A(k+1) as
+*                 dot products of rows of ( W(k) W(k+1) ) and columns
+*                 of D**(-1)
+*
+                  DO 80 J = K + 2, N
+                     A( J, K ) = T*( ( D11*W( J, K )-W( J, K+1 ) ) /
+     $                           CONJG( D21 ) )
+                     A( J, K+1 ) = T*( ( D22*W( J, K+1 )-W( J, K ) ) /
+     $                             D21 )
+   80             CONTINUE
+               END IF
+*
+*              Copy D(k) to A
+*
+               A( K, K ) = W( K, K )
+               A( K+1, K ) = W( K+1, K )
+               A( K+1, K+1 ) = W( K+1, K+1 )
+*
+*              (2) Conjugate columns W(k) and W(k+1)
+*
+               CALL CLACGV( N-K, W( K+1, K ), 1 )
+               CALL CLACGV( N-K-1, W( K+2, K+1 ), 1 )
+*
+            END IF
+*
+         END IF
+*
+*        Store details of the interchanges in IPIV
+*
+         IF( KSTEP.EQ.1 ) THEN
+            IPIV( K ) = KP
+         ELSE
+            IPIV( K ) = -P
+            IPIV( K+1 ) = -KP
+         END IF
+*
+*        Increase K and return to the start of the main loop
+*
+         K = K + KSTEP
+         GO TO 70
+*
+   90    CONTINUE
+*
+*        Update the lower triangle of A22 (= A(k:n,k:n)) as
+*
+*        A22 := A22 - L21*D*L21**H = A22 - L21*W**H
+*
+*        computing blocks of NB columns at a time (note that conjg(W) is
+*        actually stored)
+*
+         DO 110 J = K, N, NB
+            JB = MIN( NB, N-J+1 )
+*
+*           Update the lower triangle of the diagonal block
+*
+            DO 100 JJ = J, J + JB - 1
+               A( JJ, JJ ) = REAL( A( JJ, JJ ) )
+               CALL CGEMV( 'No transpose', J+JB-JJ, K-1, -CONE,
+     $                     A( JJ, 1 ), LDA, W( JJ, 1 ), LDW, CONE,
+     $                     A( JJ, JJ ), 1 )
+               A( JJ, JJ ) = REAL( A( JJ, JJ ) )
+  100       CONTINUE
+*
+*           Update the rectangular subdiagonal block
+*
+            IF( J+JB.LE.N )
+     $         CALL CGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
+     $                     K-1, -CONE, A( J+JB, 1 ), LDA, W( J, 1 ),
+     $                     LDW, CONE, A( J+JB, J ), LDA )
+  110    CONTINUE
+*
+*        Put L21 in standard form by partially undoing the interchanges
+*        of rows in columns 1:k-1 looping backwards from k-1 to 1
+*
+         J = K - 1
+  120    CONTINUE
+*
+*           Undo the interchanges (if any) of rows J and JP2
+*           (or J and JP2, and J-1 and JP1) at each step J
+*
+            KSTEP = 1
+            JP1 = 1
+*           (Here, J is a diagonal index)
+            JJ = J
+            JP2 = IPIV( J )
+            IF( JP2.LT.0 ) THEN
+               JP2 = -JP2
+*              (Here, J is a diagonal index)
+               J = J - 1
+               JP1 = -IPIV( J )
+               KSTEP = 2
+            END IF
+*           (NOTE: Here, J is used to determine row length. Length J
+*           of the rows to swap back doesn't include diagonal element)
+            J = J - 1
+            IF( JP2.NE.JJ .AND. J.GE.1 )
+     $         CALL CSWAP( J, A( JP2, 1 ), LDA, A( JJ, 1 ), LDA )
+            JJ = JJ - 1
+            IF( KSTEP.EQ.2 .AND. JP1.NE.JJ .AND. J.GE.1 )
+     $         CALL CSWAP( J, A( JP1, 1 ), LDA, A( JJ, 1 ), LDA )
+         IF( J.GT.1 )
+     $      GO TO 120
+*
+*        Set KB to the number of columns factorized
+*
+         KB = K - 1
+*
+      END IF
+      RETURN
+*
+*     End of CLAHEF_ROOK
+*
+      END
diff --git a/SRC/zlahef_rook.f b/SRC/zlahef_rook.f
new file mode 100644
index 00000000..b6626eaa
--- /dev/null
+++ b/SRC/zlahef_rook.f
@@ -0,0 +1,1125 @@
+* \brief \b ZLAHEF_ROOK computes a partial factorization of a complex Hermitian indefinite matrix using the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
+*
+*  =========== DOCUMENTATION ===========
+*
+* Online html documentation available at
+*            http://www.netlib.org/lapack/explore-html/
+*
+*> \htmlonly
+*> Download ZLAHEF_ROOK + dependencies
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlahef_rook.f">
+*> [TGZ]</a>
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlahef_rook.f">
+*> [ZIP]</a>
+*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlahef_rook.f">
+*> [TXT]</a>
+*> \endhtmlonly
+*
+*  Definition:
+*  ===========
+*
+*       SUBROUTINE ZLAHEF_ROOK( UPLO, N, NB, KB, A, LDA, IPIV, W, LDW, INFO )
+*
+*       .. Scalar Arguments ..
+*       CHARACTER          UPLO
+*       INTEGER            INFO, KB, LDA, LDW, N, NB
+*       ..
+*       .. Array Arguments ..
+*       INTEGER            IPIV( * )
+*       COMPLEX*16         A( LDA, * ), W( LDW, * )
+*       ..
+*
+*
+*> \par Purpose:
+*  =============
+*>
+*> \verbatim
+*>
+*> ZLAHEF_ROOK computes a partial factorization of a complex Hermitian
+*> matrix A using the bounded Bunch-Kaufman ("rook") diagonal pivoting
+*> method. The partial factorization has the form:
+*>
+*> A  =  ( I  U12 ) ( A11  0  ) (  I      0     )  if UPLO = 'U', or:
+*>       ( 0  U22 ) (  0   D  ) ( U12**H U22**H )
+*>
+*> A  =  ( L11  0 ) (  D   0  ) ( L11**H L21**H )  if UPLO = 'L'
+*>       ( L21  I ) (  0  A22 ) (  0      I     )
+*>
+*> where the order of D is at most NB. The actual order is returned in
+*> the argument KB, and is either NB or NB-1, or N if N <= NB.
+*> Note that U**H denotes the conjugate transpose of U.
+*>
+*> ZLAHEF_ROOK is an auxiliary routine called by ZHETRF_ROOK. It uses
+*> blocked code (calling Level 3 BLAS) to update the submatrix
+*> A11 (if UPLO = 'U') or A22 (if UPLO = 'L').
+*> \endverbatim
+*
+*  Arguments:
+*  ==========
+*
+*> \param[in] UPLO
+*> \verbatim
+*>          UPLO is CHARACTER*1
+*>          Specifies whether the upper or lower triangular part of the
+*>          Hermitian matrix A is stored:
+*>          = 'U':  Upper triangular
+*>          = 'L':  Lower triangular
+*> \endverbatim
+*>
+*> \param[in] N
+*> \verbatim
+*>          N is INTEGER
+*>          The order of the matrix A.  N >= 0.
+*> \endverbatim
+*>
+*> \param[in] NB
+*> \verbatim
+*>          NB is INTEGER
+*>          The maximum number of columns of the matrix A that should be
+*>          factored.  NB should be at least 2 to allow for 2-by-2 pivot
+*>          blocks.
+*> \endverbatim
+*>
+*> \param[out] KB
+*> \verbatim
+*>          KB is INTEGER
+*>          The number of columns of A that were actually factored.
+*>          KB is either NB-1 or NB, or N if N <= NB.
+*> \endverbatim
+*>
+*> \param[in,out] A
+*> \verbatim
+*>          A is COMPLEX*16 array, dimension (LDA,N)
+*>          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
+*>          n-by-n upper triangular part of A contains the upper
+*>          triangular part of the matrix A, and the strictly lower
+*>          triangular part of A is not referenced.  If UPLO = 'L', the
+*>          leading n-by-n lower triangular part of A contains the lower
+*>          triangular part of the matrix A, and the strictly upper
+*>          triangular part of A is not referenced.
+*>          On exit, A contains details of the partial factorization.
+*> \endverbatim
+*>
+*> \param[in] LDA
+*> \verbatim
+*>          LDA is INTEGER
+*>          The leading dimension of the array A.  LDA >= max(1,N).
+*> \endverbatim
+*>
+*> \param[out] IPIV
+*> \verbatim
+*>          IPIV is INTEGER array, dimension (N)
+*>          Details of the interchanges and the block structure of D.
+*>
+*>          If UPLO = 'U':
+*>             Only the last KB elements of IPIV are set.
+*>
+*>             If IPIV(k) > 0, then rows and columns k and IPIV(k) were
+*>             interchanged and D(k,k) is a 1-by-1 diagonal block.
+*>
+*>             If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and
+*>             columns k and -IPIV(k) were interchanged and rows and
+*>             columns k-1 and -IPIV(k-1) were inerchaged,
+*>             D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
+*>
+*>          If UPLO = 'L':
+*>             Only the first KB elements of IPIV are set.
+*>
+*>             If IPIV(k) > 0, then rows and columns k and IPIV(k)
+*>             were interchanged and D(k,k) is a 1-by-1 diagonal block.
+*>
+*>             If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and
+*>             columns k and -IPIV(k) were interchanged and rows and
+*>             columns k+1 and -IPIV(k+1) were inerchaged,
+*>             D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
+*> \endverbatim
+*>
+*> \param[out] W
+*> \verbatim
+*>          W is COMPLEX*16 array, dimension (LDW,NB)
+*> \endverbatim
+*>
+*> \param[in] LDW
+*> \verbatim
+*>          LDW is INTEGER
+*>          The leading dimension of the array W.  LDW >= max(1,N).
+*> \endverbatim
+*>
+*> \param[out] INFO
+*> \verbatim
+*>          INFO is INTEGER
+*>          = 0: successful exit
+*>          > 0: if INFO = k, D(k,k) is exactly zero.  The factorization
+*>               has been completed, but the block diagonal matrix D is
+*>               exactly singular.
+*> \endverbatim
+*
+*  Authors:
+*  ========
+*
+*> \author Univ. of Tennessee
+*> \author Univ. of California Berkeley
+*> \author Univ. of Colorado Denver
+*> \author NAG Ltd.
+*
+*> \date November 2012
+*
+*> \ingroup complex16HEcomputational
+*
+*> \par Contributors:
+*  ==================
+*>
+*> \verbatim
+*>
+*>  November 2012,  Igor Kozachenko,
+*>                  Computer Science Division,
+*>                  University of California, Berkeley
+*>
+*>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
+*>                  School of Mathematics,
+*>                  University of Manchester
+*>
+*> \endverbatim
+*
+*  =====================================================================
+      SUBROUTINE ZLAHEF_ROOK( UPLO, N, NB, KB, A, LDA, IPIV, W, LDW,
+     $                        INFO )
+*
+*  -- LAPACK computational routine (version 3.4.2) --
+*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
+*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
+*     September 2012
+*
+*     .. Scalar Arguments ..
+      CHARACTER          UPLO
+      INTEGER            INFO, KB, LDA, LDW, N, NB
+*     ..
+*     .. Array Arguments ..
+      INTEGER            IPIV( * )
+      COMPLEX*16         A( LDA, * ), W( LDW, * )
+*     ..
+*
+*  =====================================================================
+*
+*     .. Parameters ..
+      DOUBLE PRECISION   ZERO, ONE
+      PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
+      COMPLEX*16         CONE
+      PARAMETER          ( CONE = ( 1.0D+0, 0.0D+0 ) )
+      DOUBLE PRECISION   EIGHT, SEVTEN
+      PARAMETER          ( EIGHT = 8.0D+0, SEVTEN = 17.0D+0 )
+*     ..
+*     .. Local Scalars ..
+      LOGICAL            DONE
+      INTEGER            IMAX, ITEMP, II, J, JB, JJ, JMAX, JP1, JP2, K,
+     $                   KK, KKW, KP, KSTEP, KW, P
+      DOUBLE PRECISION   ABSAKK, ALPHA, COLMAX, DTEMP, R1, ROWMAX, T,
+     $                   SFMIN
+      COMPLEX*16         D11, D21, D22, Z
+*     ..
+*     .. External Functions ..
+      LOGICAL            LSAME
+      INTEGER            IZAMAX
+      DOUBLE PRECISION   DLAMCH
+      EXTERNAL           LSAME, IZAMAX, DLAMCH
+*     ..
+*     .. External Subroutines ..
+      EXTERNAL           ZCOPY, ZDSCAL, ZGEMM, ZGEMV, ZLACGV, ZSWAP
+*     ..
+*     .. Intrinsic Functions ..
+      INTRINSIC          ABS, DBLE, DCONJG, DIMAG, MAX, MIN, SQRT
+*     ..
+*     .. Statement Functions ..
+      DOUBLE PRECISION   CABS1
+*     ..
+*     .. Statement Function definitions ..
+      CABS1( Z ) = ABS( DBLE( Z ) ) + ABS( DIMAG( Z ) )
+*     ..
+*     .. Executable Statements ..
+*
+      INFO = 0
+*
+*     Initialize ALPHA for use in choosing pivot block size.
+*
+      ALPHA = ( ONE+SQRT( SEVTEN ) ) / EIGHT
+*
+*     Compute machine safe minimum
+*
+      SFMIN = DLAMCH( 'S' )
+*
+      IF( LSAME( UPLO, 'U' ) ) THEN
+*
+*        Factorize the trailing columns of A using the upper triangle
+*        of A and working backwards, and compute the matrix W = U12*D
+*        for use in updating A11
+*
+*        K is the main loop index, decreasing from N in steps of 1 or 2
+*
+         K = N
+   10    CONTINUE
+*
+*        KW is the column of W which corresponds to column K of A
+*
+         KW = NB + K - N
+*
+*        Exit from loop
+*
+         IF( ( K.LE.N-NB+1 .AND. NB.LT.N ) .OR. K.LT.1 )
+     $      GO TO 30
+*
+         KSTEP = 1
+         P = K
+*
+*        Copy column K of A to column KW of W and update it
+*
+         IF( K.GT.1 )
+     $      CALL ZCOPY( K-1, A( 1, K ), 1, W( 1, KW ), 1 )
+         W( K, KW ) = DBLE( A( K, K ) )
+         IF( K.LT.N ) THEN
+            CALL ZGEMV( 'No transpose', K, N-K, -CONE, A( 1, K+1 ), LDA,
+     $                  W( K, KW+1 ), LDW, CONE, W( 1, KW ), 1 )
+            W( K, KW ) = DBLE( W( K, KW ) )
+         END IF
+*
+*        Determine rows and columns to be interchanged and whether
+*        a 1-by-1 or 2-by-2 pivot block will be used
+*
+         ABSAKK = ABS( DBLE( W( K, K ) ) )
+*
+*        IMAX is the row-index of the largest off-diagonal element in
+*        column K, and COLMAX is its absolute value
+*
+         IF( K.GT.1 ) THEN
+            IMAX = IZAMAX( K-1, W( 1, KW ), 1 )
+            COLMAX = CABS1( W( IMAX, KW ) )
+         ELSE
+            COLMAX = ZERO
+         END IF
+*
+         IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
+*
+*           Column K is zero: set INFO and continue
+*
+            IF( INFO.EQ.0 )
+     $         INFO = K
+            KP = K
+            IF( K.GT.1 )
+     $         CALL ZCOPY( K-1, W( 1, K ), 1, A( 1, KW ), 1 )
+            A( K, K ) = DBLE( A( K, K ) )
+         ELSE
+*
+*           ============================================================
+*
+*           Test for interchange
+*
+*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
+*           (used to handle NaN and Inf)
+*
+            IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
+*
+*              no interchange, use 1-by-1 pivot block
+*
+               KP = K
+*
+            ELSE
+*
+               DONE = .FALSE.
+*
+*              Loop until pivot found
+*
+   12          CONTINUE
+*
+*                 Begin pivot search loop body
+*
+*
+*                 Copy column IMAX to column KW-1 of W and update it
+*
+                  IF( IMAX.GT.1 )
+     $               CALL ZCOPY( IMAX-1, A( 1, IMAX ), 1, W( 1, KW-1 ),
+     $                           1 )
+                  W( IMAX, KW-1 ) = DBLE( A( IMAX, IMAX ) )
+                  CALL ZCOPY( K-IMAX, A( IMAX, IMAX+1 ), LDA,
+     $                        W( IMAX+1, KW-1 ), 1 )
+                  CALL ZLACGV( K-IMAX, W( IMAX+1, KW-1 ), 1 )
+                  IF( K.LT.N ) THEN
+                     CALL ZGEMV( 'No transpose', K, N-K, -CONE,
+     $                           A( 1, K+1 ), LDA, W( IMAX, KW+1 ), LDW,
+     $                           CONE, W( 1, KW-1 ), 1 )
+                     W( IMAX, KW-1 ) = DBLE( W( IMAX, KW-1 ) )
+                  END IF
+*
+*                 JMAX is the column-index of the largest off-diagonal
+*                 element in row IMAX, and ROWMAX is its absolute value.
+*                 Determine both ROWMAX and JMAX.
+*
+                  IF( IMAX.NE.K ) THEN
+                     JMAX = IMAX + IZAMAX( K-IMAX, W( IMAX+1, KW-1 ),
+     $                                     1 )
+                     ROWMAX = CABS1( W( JMAX, KW-1 ) )
+                  ELSE
+                     ROWMAX = ZERO
+                  END IF
+*
+                  IF( IMAX.GT.1 ) THEN
+                     ITEMP = IZAMAX( IMAX-1, W( 1, KW-1 ), 1 )
+                     DTEMP = CABS1( W( ITEMP, KW-1 ) )
+                     IF( DTEMP.GT.ROWMAX ) THEN
+                        ROWMAX = DTEMP
+                        JMAX = ITEMP
+                     END IF
+                  END IF
+*
+*                 Equivalent to testing for
+*                 ABS( DBLE( W( IMAX,KW-1 ) ) ).GE.ALPHA*ROWMAX
+*                 (used to handle NaN and Inf)
+*
+                  IF( .NOT.( ABS( DBLE( W( IMAX,KW-1 ) ) )
+     $                       .LT.ALPHA*ROWMAX ) ) THEN
+*
+*                    interchange rows and columns K and IMAX,
+*                    use 1-by-1 pivot block
+*
+                     KP = IMAX
+*
+*                    copy column KW-1 of W to column KW of W
+*
+                     CALL ZCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
+*
+                     DONE = .TRUE.
+*
+*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
+*                 (used to handle NaN and Inf)
+*
+                  ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
+     $            THEN
+*
+*                    interchange rows and columns K-1 and IMAX,
+*                    use 2-by-2 pivot block
+*
+                     KP = IMAX
+                     KSTEP = 2
+                     DONE = .TRUE.
+                  ELSE
+*
+*                    Pivot not found: set params and repeat
+*
+                     P = IMAX
+                     COLMAX = ROWMAX
+                     IMAX = JMAX
+*
+*                    Copy updated JMAXth (next IMAXth) column to Kth of W
+*
+                     CALL ZCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
+*
+                  END IF
+*
+*                 End pivot search loop body
+*
+               IF( .NOT.DONE ) GOTO 12
+*
+            END IF
+*
+*           ============================================================
+*
+*           KK is the column of A where pivoting step stopped
+*
+            KK = K - KSTEP + 1
+*
+*           KKW is the column of W which corresponds to column KK of A
+*
+            KKW = NB + KK - N
+*
+*           Interchange rows and columns P and K.
+*           Updated column P is already stored in column KW of W.
+*
+            IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
+*
+*              Copy non-updated column KK+1 to column P of submatrix A
+*              at step K. No need to copy element into columns
+*              K and K-1 of A for 2-by-2 pivot, since these columns
+*              will be later overwritten.
+*
+               A( P, P ) = DBLE( A( K, K ) )
+               CALL ZCOPY( K-1-P, A( P+1, K ), 1, A( P, P+1 ),
+     $                     LDA )
+               CALL ZLACGV( K-1-P, A( P, P+1 ), LDA )
+               IF( P.GT.1 )
+     $            CALL ZCOPY( P-1, A( 1, K ), 1, A( 1, P ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K and K-1 of A for 2-by-2 pivot will be
+*              later overwritten). Interchange rows KK and KP
+*              in last KW to NB columns of W.
+*
+               IF( K.LT.N )
+     $            CALL ZSWAP( N-K, A( K, K+1 ), LDA, A( P, K+1 ),
+     $                        LDA )
+               CALL ZSWAP( N-K+1, W( K, KW ), LDW, W( P, KW ),
+     $                     LDW )
+            END IF
+*
+*           Interchange rows and columns KP and KK.
+*           Updated column KP is already stored in column KKW of W.
+*
+            IF( KP.NE.KK ) THEN
+*
+*              Copy non-updated column KK to column KP of submatrix A
+*              at step K. No need to copy element into column K
+*              (or K and K-1 for 2-by-2 pivot) of A, since these columns
+*              will be later overwritten.
+*
+               A( KP, KP ) = DBLE( A( KK, KK ) )
+               CALL ZCOPY( KK-1-KP, A( KP+1, KK ), 1, A( KP, KP+1 ),
+     $                     LDA )
+               CALL ZLACGV( KK-1-KP, A( KP, KP+1 ), LDA )
+               IF( KP.GT.1 )
+     $            CALL ZCOPY( KP-1, A( 1, KK ), 1, A( 1, KP ), 1 )
+*
+*              Interchange rows KK and KP in last K+1 to N columns of A
+*              (columns K (or K and K-1 for 2-by-2 pivot) of A will be
+*              later overwritten). Interchange rows KK and KP
+*              in last KKW to NB columns of W.
+*
+               IF( K.LT.N )
+     $            CALL ZSWAP( N-K, A( KK, K+1 ), LDA, A( KP, K+1 ),
+     $                        LDA )
+               CALL ZSWAP( N-KK+1, W( KK, KKW ), LDW, W( KP, KKW ),
+     $                     LDW )
+            END IF
+*
+            IF( KSTEP.EQ.1 ) THEN
+*
+*              1-by-1 pivot block D(k): column kw of W now holds
+*
+*              W(kw) = U(k)*D(k),
+*
+*              where U(k) is the k-th column of U
+*
+*              (1) Store subdiag. elements of column U(k)
+*              and 1-by-1 block D(k) in column k of A.
+*              (NOTE: Diagonal element U(k,k) is a UNIT element
+*              and not stored)
+*                 A(k,k) := D(k,k) = W(k,kw)
+*                 A(1:k-1,k) := U(1:k-1,k) = W(1:k-1,kw)/D(k,k)
+*
+*              (NOTE: No need to use for Hermitian matrix
+*              A( K, K ) = DBLE( W( K, K) ) to separately copy diagonal
+*              element D(k,k) from W (potentially saves only one load))
+               CALL ZCOPY( K, W( 1, KW ), 1, A( 1, K ), 1 )
+               IF( K.GT.1 ) THEN
+*
+*                 Handle division by a small number
+*
+                  T = DBLE( A( K, K ) )
+                  IF( ABS( T ).GE.SFMIN ) THEN
+                     R1 = ONE / T
+                     CALL ZDSCAL( K-1, R1, A( 1, K ), 1 )
+                  ELSE
+*                    (NOTE: No need to check if T=D(k,k) is NOT ZERO,
+*                    since that was ensured earlier in pivot search)
+                     DO 14 II = 1, K-1
+                        A( II, K ) = A( II, K ) / T
+   14                CONTINUE
+                  END IF
+*
+*                 (2) Conjugate column W(kw)
+*
+                  CALL ZLACGV( K-1, W( 1, KW ), 1 )
+               END IF
+*
+            ELSE
+*
+*              2-by-2 pivot block D(k): columns kw and kw-1 of W now hold
+*
+*              ( W(kw-1) W(kw) ) = ( U(k-1) U(k) )*D(k)
+*
+*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
+*              of U
+*
+*              (1) Store U(1:k-2,k-1) and U(1:k-2,k) and 2-by-2
+*              block D(k-1:k,k-1:k) in columns k-1 and k of A.
+*              (NOTE: 2-by-2 diagonal block U(k-1:k,k-1:k) is a UNIT
+*              block and not stored)
+*                 A(k-1:k,k-1:k) := D(k-1:k,k-1:k) = W(k-1:k,kw-1:kw)
+*                 A(1:k-2,k-1:k) := U(1:k-2,k:k-1:k) =
+*                 = W(1:k-2,kw-1:kw) * ( D(k-1:k,k-1:k)**(-1) )
+*
+               IF( K.GT.2 ) THEN
+*
+*                 Compose the columns of the inverse of 2-by-2 pivot
+*                 block D in the following way to reduce the number
+*                 of FLOPS when we myltiply panel ( W(kw-1) W(kw) ) by
+*                 this inverse
+*
+*                 D**(-1) = ( d11 cj(d21) )**(-1) =
+*                           ( d21    d22 )
+*
+*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
+*                                          ( (-d21) (     d11 ) )
+*
+*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
+*
+*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
+*                     (     (      -1 )           ( d11/conj(d21) ) )
+*
+*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
+*
+*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                     (     (  -1 )           ( D22 ) )
+*
+*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                                      (     (  -1 )           ( D22 ) )
+*
+*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
+*                   (               (  -1 )         ( D22 ) )
+*
+*                 Handle division by a small number. (NOTE: order of
+*                 operations is important)
+*
+*                 = ( T*(( D11 )/conj(D21)) T*((  -1 )/D21 ) )
+*                   (   ((  -1 )          )   (( D22 )     ) )
+*
+                  D21 = W( K-1, KW )
+                  D11 = W( K, KW ) / DCONJG( D21 )
+                  D22 = W( K-1, KW-1 ) / D21
+                  T = ONE / ( DBLE( D11*D22 )-ONE )
+*
+*                 Update elements in columns A(k-1) and A(k) as
+*                 dot products of rows of ( W(kw-1) W(kw) ) and columns
+*                 of D**(-1)
+*
+                  DO 20 J = 1, K - 2
+                     A( J, K-1 ) = T*( ( D11*W( J, KW-1 )-W( J, KW ) ) /
+     $                             D21 )
+                     A( J, K ) = T*( ( D22*W( J, KW )-W( J, KW-1 ) ) /
+     $                           DCONJG( D21 ) )
+   20             CONTINUE
+               END IF
+*
+*              Copy D(k) to A
+*
+               A( K-1, K-1 ) = W( K-1, KW-1 )
+               A( K-1, K ) = W( K-1, KW )
+               A( K, K ) = W( K, KW )
+*
+*              (2) Conjugate columns W(kw) and W(kw-1)
+*
+               CALL ZLACGV( K-1, W( 1, KW ), 1 )
+               CALL ZLACGV( K-2, W( 1, KW-1 ), 1 )
+*
+            END IF
+*
+         END IF
+*
+*        Store details of the interchanges in IPIV
+*
+         IF( KSTEP.EQ.1 ) THEN
+            IPIV( K ) = KP
+         ELSE
+            IPIV( K ) = -P
+            IPIV( K-1 ) = -KP
+         END IF
+*
+*        Decrease K and return to the start of the main loop
+*
+         K = K - KSTEP
+         GO TO 10
+*
+   30    CONTINUE
+*
+*        Update the upper triangle of A11 (= A(1:k,1:k)) as
+*
+*        A11 := A11 - U12*D*U12**H = A11 - U12*W**H
+*
+*        computing blocks of NB columns at a time (note that conjg(W) is
+*        actually stored)
+*
+         DO 50 J = ( ( K-1 ) / NB )*NB + 1, 1, -NB
+            JB = MIN( NB, K-J+1 )
+*
+*           Update the upper triangle of the diagonal block
+*
+            DO 40 JJ = J, J + JB - 1
+               A( JJ, JJ ) = DBLE( A( JJ, JJ ) )
+               CALL ZGEMV( 'No transpose', JJ-J+1, N-K, -CONE,
+     $                     A( J, K+1 ), LDA, W( JJ, KW+1 ), LDW, CONE,
+     $                     A( J, JJ ), 1 )
+               A( JJ, JJ ) = DBLE( A( JJ, JJ ) )
+   40       CONTINUE
+*
+*           Update the rectangular superdiagonal block
+*
+            CALL ZGEMM( 'No transpose', 'Transpose', J-1, JB, N-K,
+     $                  -CONE, A( 1, K+1 ), LDA, W( J, KW+1 ), LDW,
+     $                  CONE, A( 1, J ), LDA )
+   50    CONTINUE
+*
+*        Put U12 in standard form by partially undoing the interchanges
+*        in of rows in columns k+1:n looping backwards from k+1 to 1
+*
+         J = K + 1
+   60    CONTINUE
+*
+*           Undo the interchanges (if any) of rows J and JP2
+*           (or J and JP2, and J+1 and JP1) at each step J
+*
+            KSTEP = 1
+            JP1 = 1
+*           (Here, J is a diagonal index)
+            JJ = J
+            JP2 = IPIV( J )
+            IF( JP2.LT.0 ) THEN
+               JP2 = -JP2
+*              (Here, J is a diagonal index)
+               J = J + 1
+               JP1 = -IPIV( J )
+               KSTEP = 2
+            END IF
+*           (NOTE: Here, J is used to determine row length. Length N-J+1
+*           of the rows to swap back doesn't include diagonal element)
+            J = J + 1
+            IF( JP2.NE.JJ .AND. J.LE.N )
+     $         CALL ZSWAP( N-J+1, A( JP2, J ), LDA, A( JJ, J ), LDA )
+            JJ = JJ + 1
+            IF( JP1.NE.JJ .AND. KSTEP.EQ.2 .AND. J.LE.N )
+     $         CALL ZSWAP( N-J+1, A( JP1, J ), LDA, A( JJ, J ), LDA )
+         IF( J.LT.N )
+     $      GO TO 60
+*
+*        Set KB to the number of columns factorized
+*
+         KB = N - K
+*
+      ELSE
+*
+*        Factorize the leading columns of A using the lower triangle
+*        of A and working forwards, and compute the matrix W = L21*D
+*        for use in updating A22
+*
+*        K is the main loop index, increasing from 1 in steps of 1 or 2
+*
+         K = 1
+   70    CONTINUE
+*
+         IF( ( K.GE.NB .AND. NB.LT.N ) .OR. K.GT.N )
+     $      GO TO 90
+*
+         KSTEP = 1
+         P = K
+*
+*        Copy column K of A to column K of W and update column K of W
+*
+         W( K, K ) = DBLE( A( K, K ) )
+         IF( K.LT.N )
+     $      CALL ZCOPY( N-K, A( K+1, K ), 1, W( K+1, K ), 1 )
+         IF( K.GT.1 ) THEN
+            CALL ZGEMV( 'No transpose', N-K+1, K-1, -CONE, A( K, 1 ),
+     $                  LDA, W( K, 1 ), LDW, CONE, W( K, K ), 1 )
+            W( K, K ) = DBLE( W( K, K ) )
+         END IF
+*
+*        Determine rows and columns to be interchanged and whether
+*        a 1-by-1 or 2-by-2 pivot block will be used
+*
+         ABSAKK = ABS( DBLE( W( K, K ) ) )
+*
+*        IMAX is the row-index of the largest off-diagonal element in
+*        column K, and COLMAX is its absolute value
+*
+         IF( K.LT.N ) THEN
+            IMAX = K + IZAMAX( N-K, W( K+1, K ), 1 )
+            COLMAX = CABS1( W( IMAX, K ) )
+         ELSE
+            COLMAX = ZERO
+         END IF
+*
+         IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
+*
+*           Column K is zero: set INFO and continue
+*
+            IF( INFO.EQ.0 )
+     $         INFO = K
+            KP = K
+            A( K, K ) = DBLE( A( K, K ) )
+            IF( K.LT.N )
+     $         CALL ZCOPY( N-K, W( K+1, K ), 1, A( K+1, K ), 1 )
+         ELSE
+*
+*           ============================================================
+*
+*           Test for interchange
+*
+*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
+*           (used to handle NaN and Inf)
+*
+            IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
+*
+*              no interchange, use 1-by-1 pivot block
+*
+               KP = K
+*
+            ELSE
+*
+               DONE = .FALSE.
+*
+*              Loop until pivot found
+*
+   72          CONTINUE
+*
+*                 Begin pivot search loop body
+*
+*
+*                 Copy column IMAX to column k+1 of W and update it
+*
+                  CALL ZCOPY( IMAX-K, A( IMAX, K ), LDA, W( K, K+1 ), 1)
+                  CALL ZLACGV( IMAX-K, W( K, K+1 ), 1 )
+                  W( IMAX, K+1 ) = DBLE( A( IMAX, IMAX ) )
+                  IF( IMAX.LT.N )
+     $               CALL ZCOPY( N-IMAX, A( IMAX+1, IMAX ), 1,
+     $                           W( IMAX+1, K+1 ), 1 )
+                  IF( K.GT.1 ) THEN
+                     CALL ZGEMV( 'No transpose', N-K+1, K-1, -CONE,
+     $                            A( K, 1 ), LDA, W( IMAX, 1 ), LDW,
+     $                            CONE, W( K, K+1 ), 1 )
+                     W( IMAX, K+1 ) = DBLE( W( IMAX, K+1 ) )
+                  END IF
+*
+*                 JMAX is the column-index of the largest off-diagonal
+*                 element in row IMAX, and ROWMAX is its absolute value.
+*                 Determine both ROWMAX and JMAX.
+*
+                  IF( IMAX.NE.K ) THEN
+                     JMAX = K - 1 + IZAMAX( IMAX-K, W( K, K+1 ), 1 )
+                     ROWMAX = CABS1( W( JMAX, K+1 ) )
+                  ELSE
+                     ROWMAX = ZERO
+                  END IF
+*
+                  IF( IMAX.LT.N ) THEN
+                     ITEMP = IMAX + IZAMAX( N-IMAX, W( IMAX+1, K+1 ), 1)
+                     DTEMP = CABS1( W( ITEMP, K+1 ) )
+                     IF( DTEMP.GT.ROWMAX ) THEN
+                        ROWMAX = DTEMP
+                        JMAX = ITEMP
+                     END IF
+                  END IF
+*
+*                 Equivalent to testing for
+*                 ABS( DBLE( W( IMAX,K+1 ) ) ).GE.ALPHA*ROWMAX
+*                 (used to handle NaN and Inf)
+*
+                  IF( .NOT.( ABS( DBLE( W( IMAX,K+1 ) ) )
+     $                       .LT.ALPHA*ROWMAX ) ) THEN
+*
+*                    interchange rows and columns K and IMAX,
+*                    use 1-by-1 pivot block
+*
+                     KP = IMAX
+*
+*                    copy column K+1 of W to column K of W
+*
+                     CALL ZCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
+*
+                     DONE = .TRUE.
+*
+*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
+*                 (used to handle NaN and Inf)
+*
+                  ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
+     $            THEN
+*
+*                    interchange rows and columns K+1 and IMAX,
+*                    use 2-by-2 pivot block
+*
+                     KP = IMAX
+                     KSTEP = 2
+                     DONE = .TRUE.
+                  ELSE
+*
+*                    Pivot not found: set params and repeat
+*
+                     P = IMAX
+                     COLMAX = ROWMAX
+                     IMAX = JMAX
+*
+*                    Copy updated JMAXth (next IMAXth) column to Kth of W
+*
+                     CALL ZCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
+*
+                  END IF
+*
+*                 End pivot search loop body
+*
+               IF( .NOT.DONE ) GOTO 72
+*
+            END IF
+*
+*           ============================================================
+*
+*           KK is the column of A where pivoting step stopped
+*
+            KK = K + KSTEP - 1
+*
+*           Interchange rows and columns P and K (only for 2-by-2 pivot).
+*           Updated column P is already stored in column K of W.
+*
+            IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
+*
+*              Copy non-updated column KK-1 to column P of submatrix A
+*              at step K. No need to copy element into columns
+*              K and K+1 of A for 2-by-2 pivot, since these columns
+*              will be later overwritten.
+*
+               A( P, P ) = DBLE( A( K, K ) )
+               CALL ZCOPY( P-K-2, A( K+2, K ), 1, A( P, K+2 ), LDA )
+               CALL ZLACGV( P-K-1, A( P, K+1 ), LDA )
+               IF( P.LT.N )
+     $            CALL ZCOPY( N-P, A( P+1, K ), 1, A( P+1, P ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K and K+1 of A for 2-by-2 pivot will be
+*              later overwritten). Interchange rows KK and KP
+*              in first KK columns of W.
+*
+               IF( K.GT.1 )
+     $            CALL ZSWAP( K-1, A( K, 1 ), LDA, A( P, 1 ), LDA )
+               CALL ZSWAP( K, W( K, 1 ), LDW, W( P, 1 ), LDW )
+            END IF
+*
+*           Interchange rows and columns KP and KK.
+*           Updated column KP is already stored in column KK of W.
+*
+            IF( KP.NE.KK ) THEN
+*
+*              Copy non-updated column KK to column KP of submatrix A
+*              at step K. No need to copy element into column K
+*              (or K and K+1 for 2-by-2 pivot) of A, since these columns
+*              will be later overwritten.
+*
+               A( KP, KP ) = DBLE( A( KK, KK ) )
+               CALL ZCOPY( KP-KK-1, A( KK+1, KK ), 1, A( KP, KK+1 ),
+     $                     LDA )
+               CALL ZLACGV( KP-KK-1, A( KP, KK+1 ), LDA )
+               IF( KP.LT.N )
+     $            CALL ZCOPY( N-KP, A( KP+1, KK ), 1, A( KP+1, KP ), 1 )
+*
+*              Interchange rows KK and KP in first K-1 columns of A
+*              (columns K (or K and K+1 for 2-by-2 pivot) of A will be
+*              later overwritten). Interchange rows KK and KP
+*              in first KK columns of W.
+*
+               IF( K.GT.1 )
+     $            CALL ZSWAP( K-1, A( KK, 1 ), LDA, A( KP, 1 ), LDA )
+               CALL ZSWAP( KK, W( KK, 1 ), LDW, W( KP, 1 ), LDW )
+            END IF
+*
+            IF( KSTEP.EQ.1 ) THEN
+*
+*              1-by-1 pivot block D(k): column k of W now holds
+*
+*              W(k) = L(k)*D(k),
+*
+*              where L(k) is the k-th column of L
+*
+*              (1) Store subdiag. elements of column L(k)
+*              and 1-by-1 block D(k) in column k of A.
+*              (NOTE: Diagonal element L(k,k) is a UNIT element
+*              and not stored)
+*                 A(k,k) := D(k,k) = W(k,k)
+*                 A(k+1:N,k) := L(k+1:N,k) = W(k+1:N,k)/D(k,k)
+*
+*              (NOTE: No need to use for Hermitian matrix
+*              A( K, K ) = DBLE( W( K, K) ) to separately copy diagonal
+*              element D(k,k) from W (potentially saves only one load))
+               CALL ZCOPY( N-K+1, W( K, K ), 1, A( K, K ), 1 )
+               IF( K.LT.N ) THEN
+*
+*                 Handle division by a small number
+*
+                  T = DBLE( A( K, K ) )
+                  IF( ABS( T ).GE.SFMIN ) THEN
+                     R1 = ONE / T
+                     CALL ZDSCAL( N-K, R1, A( K+1, K ), 1 )
+                  ELSE
+*                    (NOTE: No need to check if T=D(k,k) is NOT ZERO,
+*                    since that was ensured earlier in pivot search)
+                     DO 74 II = K + 1, N
+                        A( II, K ) = A( II, K ) / T
+   74                CONTINUE
+                  END IF
+*
+*                 (2) Conjugate column W(k)
+*
+                  CALL ZLACGV( N-K, W( K+1, K ), 1 )
+               END IF
+*
+            ELSE
+*
+*              2-by-2 pivot block D(k): columns k and k+1 of W now hold
+*
+*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
+*
+*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
+*              of L
+*
+*              (1) Store L(k+2:N,k) and L(k+2:N,k+1) and 2-by-2
+*              block D(k:k+1,k:k+1) in columns k and k+1 of A.
+*              NOTE: 2-by-2 diagonal block L(k:k+1,k:k+1) is a UNIT
+*              block and not stored.
+*                 A(k:k+1,k:k+1) := D(k:k+1,k:k+1) = W(k:k+1,k:k+1)
+*                 A(k+2:N,k:k+1) := L(k+2:N,k:k+1) =
+*                 = W(k+2:N,k:k+1) * ( D(k:k+1,k:k+1)**(-1) )
+*
+               IF( K.LT.N-1 ) THEN
+*
+*                 Compose the columns of the inverse of 2-by-2 pivot
+*                 block D in the following way to reduce the number
+*                 of FLOPS when we myltiply panel ( W(k) W(k+1) ) by
+*                 this inverse
+*
+*                 D**(-1) = ( d11 cj(d21) )**(-1) =
+*                           ( d21    d22 )
+*
+*                 = 1/(d11*d22-|d21|**2) * ( ( d22) (-cj(d21) ) ) =
+*                                          ( (-d21) (     d11 ) )
+*
+*                 = 1/(|d21|**2) * 1/((d11/cj(d21))*(d22/d21)-1) *
+*
+*                   * ( d21*( d22/d21 ) conj(d21)*(           - 1 ) ) =
+*                     (     (      -1 )           ( d11/conj(d21) ) )
+*
+*                 = 1/(|d21|**2) * 1/(D22*D11-1) *
+*
+*                   * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                     (     (  -1 )           ( D22 ) )
+*
+*                 = (1/|d21|**2) * T * ( d21*( D11 ) conj(d21)*(  -1 ) ) =
+*                                      (     (  -1 )           ( D22 ) )
+*
+*                 = ( (T/conj(d21))*( D11 ) (T/d21)*(  -1 ) ) =
+*                   (               (  -1 )         ( D22 ) )
+*
+*                 Handle division by a small number. (NOTE: order of
+*                 operations is important)
+*
+*                 = ( T*(( D11 )/conj(D21)) T*((  -1 )/D21 ) )
+*                   (   ((  -1 )          )   (( D22 )     ) )
+*
+                  D21 = W( K+1, K )
+                  D11 = W( K+1, K+1 ) / D21
+                  D22 = W( K, K ) / DCONJG( D21 )
+                  T = ONE / ( DBLE( D11*D22 )-ONE )
+*
+*                 Update elements in columns A(k) and A(k+1) as
+*                 dot products of rows of ( W(k) W(k+1) ) and columns
+*                 of D**(-1)
+*
+                  DO 80 J = K + 2, N
+                     A( J, K ) = T*( ( D11*W( J, K )-W( J, K+1 ) ) /
+     $                           DCONJG( D21 ) )
+                     A( J, K+1 ) = T*( ( D22*W( J, K+1 )-W( J, K ) ) /
+     $                             D21 )
+   80             CONTINUE
+               END IF
+*
+*              Copy D(k) to A
+*
+               A( K, K ) = W( K, K )
+               A( K+1, K ) = W( K+1, K )
+               A( K+1, K+1 ) = W( K+1, K+1 )
+*
+*              (2) Conjugate columns W(k) and W(k+1)
+*
+               CALL ZLACGV( N-K, W( K+1, K ), 1 )
+               CALL ZLACGV( N-K-1, W( K+2, K+1 ), 1 )
+*
+            END IF
+*
+         END IF
+*
+*        Store details of the interchanges in IPIV
+*
+         IF( KSTEP.EQ.1 ) THEN
+            IPIV( K ) = KP
+         ELSE
+            IPIV( K ) = -P
+            IPIV( K+1 ) = -KP
+         END IF
+*
+*        Increase K and return to the start of the main loop
+*
+         K = K + KSTEP
+         GO TO 70
+*
+   90    CONTINUE
+*
+*        Update the lower triangle of A22 (= A(k:n,k:n)) as
+*
+*        A22 := A22 - L21*D*L21**H = A22 - L21*W**H
+*
+*        computing blocks of NB columns at a time (note that conjg(W) is
+*        actually stored)
+*
+         DO 110 J = K, N, NB
+            JB = MIN( NB, N-J+1 )
+*
+*           Update the lower triangle of the diagonal block
+*
+            DO 100 JJ = J, J + JB - 1
+               A( JJ, JJ ) = DBLE( A( JJ, JJ ) )
+               CALL ZGEMV( 'No transpose', J+JB-JJ, K-1, -CONE,
+     $                     A( JJ, 1 ), LDA, W( JJ, 1 ), LDW, CONE,
+     $                     A( JJ, JJ ), 1 )
+               A( JJ, JJ ) = DBLE( A( JJ, JJ ) )
+  100       CONTINUE
+*
+*           Update the rectangular subdiagonal block
+*
+            IF( J+JB.LE.N )
+     $         CALL ZGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
+     $                     K-1, -CONE, A( J+JB, 1 ), LDA, W( J, 1 ),
+     $                     LDW, CONE, A( J+JB, J ), LDA )
+  110    CONTINUE
+*
+*        Put L21 in standard form by partially undoing the interchanges
+*        of rows in columns 1:k-1 looping backwards from k-1 to 1
+*
+         J = K - 1
+  120    CONTINUE
+*
+*           Undo the interchanges (if any) of rows J and JP2
+*           (or J and JP2, and J-1 and JP1) at each step J
+*
+            KSTEP = 1
+            JP1 = 1
+*           (Here, J is a diagonal index)
+            JJ = J
+            JP2 = IPIV( J )
+            IF( JP2.LT.0 ) THEN
+               JP2 = -JP2
+*              (Here, J is a diagonal index)
+               J = J - 1
+               JP1 = -IPIV( J )
+               KSTEP = 2
+            END IF
+*           (NOTE: Here, J is used to determine row length. Length J
+*           of the rows to swap back doesn't include diagonal element)
+            J = J - 1
+            IF( JP2.NE.JJ .AND. J.GE.1 )
+     $         CALL ZSWAP( J, A( JP2, 1 ), LDA, A( JJ, 1 ), LDA )
+            JJ = JJ - 1
+            IF( KSTEP.EQ.2 .AND. JP1.NE.JJ .AND. J.GE.1 )
+     $         CALL ZSWAP( J, A( JP1, 1 ), LDA, A( JJ, 1 ), LDA )
+         IF( J.GT.1 )
+     $      GO TO 120
+*
+*        Set KB to the number of columns factorized
+*
+         KB = K - 1
+*
+      END IF
+      RETURN
+*
+*     End of ZLAHEF_ROOK
+*
+      END