1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
|
SUBROUTINE DGEMQRT( SIDE, TRANS, M, N, K, NB, V, LDV, T, LDT,
$ C, LDC, WORK, INFO )
IMPLICIT NONE
*
* -- LAPACK routine (version 3.?) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd. --
* -- July 2011 --
*
* .. Scalar Arguments ..
CHARACTER SIDE, TRANS
INTEGER INFO, K, LDV, LDC, M, N, NB, LDT
* ..
* .. Array Arguments ..
DOUBLE PRECISION V( LDV, * ), C( LDC, * ), T( LDT, * ), WORK( * )
* ..
*
* Purpose
* =======
*
* DGEMQRT overwrites the general real M-by-N matrix C with
*
* SIDE = 'L' SIDE = 'R'
* TRANS = 'N': Q C C Q
* TRANS = 'T': Q**T C C Q**T
*
* where Q is a real orthogonal matrix defined as the product of K
* elementary reflectors:
*
* Q = H(1) H(2) . . . H(K) = I - V T V**T
*
* generated using the compact WY representation as returned by DGEQRT.
*
* Q is of order M if SIDE = 'L' and of order N if SIDE = 'R'.
*
* Arguments
* =========
*
* SIDE (input) CHARACTER*1
* = 'L': apply Q or Q**T from the Left;
* = 'R': apply Q or Q**T from the Right.
*
* TRANS (input) CHARACTER*1
* = 'N': No transpose, apply Q;
* = 'C': Transpose, apply Q**T.
*
* M (input) INTEGER
* The number of rows of the matrix C. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix C. N >= 0.
*
* K (input) INTEGER
* The number of elementary reflectors whose product defines
* the matrix Q.
* If SIDE = 'L', M >= K >= 0;
* if SIDE = 'R', N >= K >= 0.
*
* NB (input) INTEGER
* The block size used for the storage of T. K >= NB >= 1.
* This must be the same value of NB used to generate T
* in CGEQRT.
*
* V (input) DOUBLE PRECISION array, dimension (LDV,K)
* The i-th column must contain the vector which defines the
* elementary reflector H(i), for i = 1,2,...,k, as returned by
* CGEQRT in the first K columns of its array argument A.
*
* LDV (input) INTEGER
* The leading dimension of the array V.
* If SIDE = 'L', LDA >= max(1,M);
* if SIDE = 'R', LDA >= max(1,N).
*
* T (input) DOUBLE PRECISION array, dimension (LDT,K)
* The upper triangular factors of the block reflectors
* as returned by CGEQRT, stored as a NB-by-N matrix.
*
* LDT (input) INTEGER
* The leading dimension of the array T. LDT >= NB.
*
* C (input/output) DOUBLE PRECISION array, dimension (LDC,N)
* On entry, the M-by-N matrix C.
* On exit, C is overwritten by Q C, Q**T C, C Q**T or C Q.
*
* LDC (input) INTEGER
* The leading dimension of the array C. LDC >= max(1,M).
*
* WORK (workspace/output) DOUBLE PRECISION array. The dimension of
* WORK is N*NB if SIDE = 'L', or M*NB if SIDE = 'R'.
*
* INFO (output) INTEGER
* = 0: successful exit
* < 0: if INFO = -i, the i-th argument had an illegal value
*
* =====================================================================
*
* ..
* .. Local Scalars ..
LOGICAL LEFT, RIGHT, TRAN, NOTRAN
INTEGER I, IB, LDWORK, KF, Q
* ..
* .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
* ..
* .. External Subroutines ..
EXTERNAL XERBLA, DLARFB
* ..
* .. Intrinsic Functions ..
INTRINSIC MAX, MIN
* ..
* .. Executable Statements ..
*
* .. Test the input arguments ..
*
INFO = 0
LEFT = LSAME( SIDE, 'L' )
RIGHT = LSAME( SIDE, 'R' )
TRAN = LSAME( TRANS, 'T' )
NOTRAN = LSAME( TRANS, 'N' )
*
IF( LEFT ) THEN
LDWORK = MAX( 1, N )
Q = M
ELSE IF ( RIGHT ) THEN
LDWORK = MAX( 1, M )
Q = N
END IF
IF( .NOT.LEFT .AND. .NOT.RIGHT ) THEN
INFO = -1
ELSE IF( .NOT.TRAN .AND. .NOT.NOTRAN ) THEN
INFO = -2
ELSE IF( M.LT.0 ) THEN
INFO = -3
ELSE IF( N.LT.0 ) THEN
INFO = -4
ELSE IF( K.LT.0 .OR. K.GT.Q ) THEN
INFO = -5
ELSE IF( NB.LT.1 .OR. NB.GT.K ) THEN
INFO = -6
ELSE IF( LDV.LT.MAX( 1, Q ) ) THEN
INFO = -8
ELSE IF( LDT.LT.NB ) THEN
INFO = -10
ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
INFO = -12
END IF
*
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'DGEMQRT', -INFO )
RETURN
END IF
*
* .. Quick return if possible ..
*
IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) RETURN
*
IF( LEFT .AND. TRAN ) THEN
*
DO I = 1, K, NB
IB = MIN( NB, K-I+1 )
CALL DLARFB( 'L', 'T', 'F', 'C', M-I+1, N, IB,
$ V( I, I ), LDV, T( 1, I ), LDT,
$ C( I, 1 ), LDC, WORK, LDWORK )
END DO
*
ELSE IF( RIGHT .AND. NOTRAN ) THEN
*
DO I = 1, K, NB
IB = MIN( NB, K-I+1 )
CALL DLARFB( 'R', 'N', 'F', 'C', M, N-I+1, IB,
$ V( I, I ), LDV, T( 1, I ), LDT,
$ C( 1, I ), LDC, WORK, LDWORK )
END DO
*
ELSE IF( LEFT .AND. NOTRAN ) THEN
*
KF = ((K-1)/NB)*NB+1
DO I = KF, 1, -NB
IB = MIN( NB, K-I+1 )
CALL DLARFB( 'L', 'N', 'F', 'C', M-I+1, N, IB,
$ V( I, I ), LDV, T( 1, I ), LDT,
$ C( I, 1 ), LDC, WORK, LDWORK )
END DO
*
ELSE IF( RIGHT .AND. TRAN ) THEN
*
KF = ((K-1)/NB)*NB+1
DO I = KF, 1, -NB
IB = MIN( NB, K-I+1 )
CALL DLARFB( 'R', 'T', 'F', 'C', M, N-I+1, IB,
$ V( I, I ), LDV, T( 1, I ), LDT,
$ C( 1, I ), LDC, WORK, LDWORK )
END DO
*
END IF
*
RETURN
*
* End of DGEMQRT
*
END
|
