1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
SUBROUTINE ZGEQRT( M, N, NB, A, LDA, T, LDT, WORK, INFO )
IMPLICIT NONE
*
* -- LAPACK routine (version 3.?) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* -- July 2011 --
*
* .. Scalar Arguments ..
INTEGER INFO, LDA, LDT, M, N, NB
* ..
* .. Array Arguments ..
COMPLEX*16 A( LDA, * ), T( LDT, * ), WORK( * )
* ..
*
* Purpose
* =======
*
* ZGEQRT computes a blocked QR factorization of a complex M-by-N matrix A
* using the compact WY representation of Q.
*
* Arguments
* =========
*
* M (input) INTEGER
* The number of rows of the matrix A. M >= 0.
*
* N (input) INTEGER
* The number of columns of the matrix A. N >= 0.
*
* NB (input) INTEGER
* The block size to be used in the blocked QR. MIN(M,N) >= NB >= 1.
*
* A (input/output) COMPLEX*16 array, dimension (LDA,N)
* On entry, the M-by-N matrix A.
* On exit, the elements on and above the diagonal of the array
* contain the min(M,N)-by-N upper trapezoidal matrix R (R is
* upper triangular if M >= N); the elements below the diagonal
* are the columns of V.
*
* LDA (input) INTEGER
* The leading dimension of the array A. LDA >= max(1,M).
*
* T (output) COMPLEX*16 array, dimension (LDT,MIN(M,N))
* The upper triangular block reflectors stored in compact form
* as a sequence of upper triangular blocks. See below
* for further details.
*
* LDT (input) INTEGER
* The leading dimension of the array T. LDT >= NB.
*
* WORK (workspace) COMPLEX*16 array, dimension (NB*N)
*
* INFO (output) INTEGER
* = 0: successful exit
* < 0: if INFO = -i, the i-th argument had an illegal value
*
* Further Details
* ===============
*
* The matrix V stores the elementary reflectors H(i) in the i-th column
* below the diagonal. For example, if M=5 and N=3, the matrix V is
*
* V = ( 1 )
* ( v1 1 )
* ( v1 v2 1 )
* ( v1 v2 v3 )
* ( v1 v2 v3 )
*
* where the vi's represent the vectors which define H(i), which are returned
* in the matrix A. The 1's along the diagonal of V are not stored in A.
*
* Let K=MIN(M,N). The number of blocks is B = ceiling(K/NB), where each
* block is of order NB except for the last block, which is of order
* IB = K - (B-1)*NB. For each of the B blocks, a upper triangular block
* reflector factor is computed: T1, T2, ..., TB. The NB-by-NB (and IB-by-IB
* for the last block) T's are stored in the NB-by-N matrix T as
*
* T = (T1 T2 ... TB).
*
* =====================================================================
*
* ..
* .. Local Scalars ..
INTEGER I, IB, IINFO, K
LOGICAL USE_RECURSIVE_QR
PARAMETER( USE_RECURSIVE_QR=.TRUE. )
* ..
* .. External Subroutines ..
EXTERNAL ZGEQRT2, ZGEQRT3, ZLARFB, XERBLA
* ..
* .. Executable Statements ..
*
* Test the input arguments
*
INFO = 0
IF( M.LT.0 ) THEN
INFO = -1
ELSE IF( N.LT.0 ) THEN
INFO = -2
ELSE IF( NB.LT.1 .OR. NB.GT.MIN(M,N) ) THEN
INFO = -3
ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
INFO = -5
ELSE IF( LDT.LT.NB ) THEN
INFO = -7
END IF
IF( INFO.NE.0 ) THEN
CALL XERBLA( 'ZGEQRT', -INFO )
RETURN
END IF
*
* Quick return if possible
*
K = MIN( M, N )
IF( K.EQ.0 ) RETURN
*
* Blocked loop of length K
*
DO I = 1, K, NB
IB = MIN( K-I+1, NB )
*
* Compute the QR factorization of the current block A(I:M,I:I+IB-1)
*
IF( USE_RECURSIVE_QR ) THEN
CALL ZGEQRT3( M-I+1, IB, A(I,I), LDA, T(1,I), LDT, IINFO )
ELSE
CALL ZGEQRT2( M-I+1, IB, A(I,I), LDA, T(1,I), LDT, IINFO )
END IF
IF( I+IB.LE.N ) THEN
*
* Update by applying H**H to A(I:M,I+IB:N) from the left
*
CALL ZLARFB( 'L', 'C', 'F', 'C', M-I+1, N-I-IB+1, IB,
$ A( I, I ), LDA, T( 1, I ), LDT,
$ A( I, I+IB ), LDA, WORK , N-I-IB+1 )
END IF
END DO
RETURN
*
* End of ZGEQRT
*
END
|
