1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
|
*> \brief \b CBDT02
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE CBDT02( M, N, B, LDB, C, LDC, U, LDU, WORK, RWORK,
* RESID )
*
* .. Scalar Arguments ..
* INTEGER LDB, LDC, LDU, M, N
* REAL RESID
* ..
* .. Array Arguments ..
* REAL RWORK( * )
* COMPLEX B( LDB, * ), C( LDC, * ), U( LDU, * ),
* $ WORK( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> CBDT02 tests the change of basis C = U' * B by computing the residual
*>
*> RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),
*>
*> where B and C are M by N matrices, U is an M by M orthogonal matrix,
*> and EPS is the machine precision.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] M
*> \verbatim
*> M is INTEGER
*> The number of rows of the matrices B and C and the order of
*> the matrix Q.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of columns of the matrices B and C.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*> B is COMPLEX array, dimension (LDB,N)
*> The m by n matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*> LDB is INTEGER
*> The leading dimension of the array B. LDB >= max(1,M).
*> \endverbatim
*>
*> \param[in] C
*> \verbatim
*> C is COMPLEX array, dimension (LDC,N)
*> The m by n matrix C, assumed to contain U' * B.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*> LDC is INTEGER
*> The leading dimension of the array C. LDC >= max(1,M).
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*> U is COMPLEX array, dimension (LDU,M)
*> The m by m orthogonal matrix U.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*> LDU is INTEGER
*> The leading dimension of the array U. LDU >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is COMPLEX array, dimension (M)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*> RESID is REAL
*> RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup complex_eig
*
* =====================================================================
SUBROUTINE CBDT02( M, N, B, LDB, C, LDC, U, LDU, WORK, RWORK,
$ RESID )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
INTEGER LDB, LDC, LDU, M, N
REAL RESID
* ..
* .. Array Arguments ..
REAL RWORK( * )
COMPLEX B( LDB, * ), C( LDC, * ), U( LDU, * ),
$ WORK( * )
* ..
*
* ======================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
* ..
* .. Local Scalars ..
INTEGER J
REAL BNORM, EPS, REALMN
* ..
* .. External Functions ..
REAL CLANGE, SCASUM, SLAMCH
EXTERNAL CLANGE, SCASUM, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL CCOPY, CGEMV
* ..
* .. Intrinsic Functions ..
INTRINSIC CMPLX, MAX, MIN, REAL
* ..
* .. Executable Statements ..
*
* Quick return if possible
*
RESID = ZERO
IF( M.LE.0 .OR. N.LE.0 )
$ RETURN
REALMN = REAL( MAX( M, N ) )
EPS = SLAMCH( 'Precision' )
*
* Compute norm( B - U * C )
*
DO 10 J = 1, N
CALL CCOPY( M, B( 1, J ), 1, WORK, 1 )
CALL CGEMV( 'No transpose', M, M, -CMPLX( ONE ), U, LDU,
$ C( 1, J ), 1, CMPLX( ONE ), WORK, 1 )
RESID = MAX( RESID, SCASUM( M, WORK, 1 ) )
10 CONTINUE
*
* Compute norm of B.
*
BNORM = CLANGE( '1', M, N, B, LDB, RWORK )
*
IF( BNORM.LE.ZERO ) THEN
IF( RESID.NE.ZERO )
$ RESID = ONE / EPS
ELSE
IF( BNORM.GE.RESID ) THEN
RESID = ( RESID / BNORM ) / ( REALMN*EPS )
ELSE
IF( BNORM.LT.ONE ) THEN
RESID = ( MIN( RESID, REALMN*BNORM ) / BNORM ) /
$ ( REALMN*EPS )
ELSE
RESID = MIN( RESID / BNORM, REALMN ) / ( REALMN*EPS )
END IF
END IF
END IF
RETURN
*
* End of CBDT02
*
END
|
