1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
|
*> \brief \b CGET22
*
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE CGET22( TRANSA, TRANSE, TRANSW, N, A, LDA, E, LDE, W,
* WORK, RWORK, RESULT )
*
* .. Scalar Arguments ..
* CHARACTER TRANSA, TRANSE, TRANSW
* INTEGER LDA, LDE, N
* ..
* .. Array Arguments ..
* REAL RESULT( 2 ), RWORK( * )
* COMPLEX A( LDA, * ), E( LDE, * ), W( * ), WORK( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> CGET22 does an eigenvector check.
*>
*> The basic test is:
*>
*> RESULT(1) = | A E - E W | / ( |A| |E| ulp )
*>
*> using the 1-norm. It also tests the normalization of E:
*>
*> RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )
*> j
*>
*> where E(j) is the j-th eigenvector, and m-norm is the max-norm of a
*> vector. The max-norm of a complex n-vector x in this case is the
*> maximum of |re(x(i)| + |im(x(i)| over i = 1, ..., n.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] TRANSA
*> \verbatim
*> TRANSA is CHARACTER*1
*> Specifies whether or not A is transposed.
*> = 'N': No transpose
*> = 'T': Transpose
*> = 'C': Conjugate transpose
*> \endverbatim
*>
*> \param[in] TRANSE
*> \verbatim
*> TRANSE is CHARACTER*1
*> Specifies whether or not E is transposed.
*> = 'N': No transpose, eigenvectors are in columns of E
*> = 'T': Transpose, eigenvectors are in rows of E
*> = 'C': Conjugate transpose, eigenvectors are in rows of E
*> \endverbatim
*>
*> \param[in] TRANSW
*> \verbatim
*> TRANSW is CHARACTER*1
*> Specifies whether or not W is transposed.
*> = 'N': No transpose
*> = 'T': Transpose, same as TRANSW = 'N'
*> = 'C': Conjugate transpose, use -WI(j) instead of WI(j)
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The order of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is COMPLEX array, dimension (LDA,N)
*> The matrix whose eigenvectors are in E.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*> E is COMPLEX array, dimension (LDE,N)
*> The matrix of eigenvectors. If TRANSE = 'N', the eigenvectors
*> are stored in the columns of E, if TRANSE = 'T' or 'C', the
*> eigenvectors are stored in the rows of E.
*> \endverbatim
*>
*> \param[in] LDE
*> \verbatim
*> LDE is INTEGER
*> The leading dimension of the array E. LDE >= max(1,N).
*> \endverbatim
*>
*> \param[in] W
*> \verbatim
*> W is COMPLEX array, dimension (N)
*> The eigenvalues of A.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is COMPLEX array, dimension (N*N)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*> RWORK is REAL array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*> RESULT is REAL array, dimension (2)
*> RESULT(1) = | A E - E W | / ( |A| |E| ulp )
*> RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup complex_eig
*
* =====================================================================
SUBROUTINE CGET22( TRANSA, TRANSE, TRANSW, N, A, LDA, E, LDE, W,
$ WORK, RWORK, RESULT )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
CHARACTER TRANSA, TRANSE, TRANSW
INTEGER LDA, LDE, N
* ..
* .. Array Arguments ..
REAL RESULT( 2 ), RWORK( * )
COMPLEX A( LDA, * ), E( LDE, * ), W( * ), WORK( * )
* ..
*
* =====================================================================
*
* .. Parameters ..
REAL ZERO, ONE
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
COMPLEX CZERO, CONE
PARAMETER ( CZERO = ( 0.0E+0, 0.0E+0 ),
$ CONE = ( 1.0E+0, 0.0E+0 ) )
* ..
* .. Local Scalars ..
CHARACTER NORMA, NORME
INTEGER ITRNSE, ITRNSW, J, JCOL, JOFF, JROW, JVEC
REAL ANORM, ENORM, ENRMAX, ENRMIN, ERRNRM, TEMP1,
$ ULP, UNFL
COMPLEX WTEMP
* ..
* .. External Functions ..
LOGICAL LSAME
REAL CLANGE, SLAMCH
EXTERNAL LSAME, CLANGE, SLAMCH
* ..
* .. External Subroutines ..
EXTERNAL CGEMM, CLASET
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, AIMAG, CONJG, MAX, MIN, REAL
* ..
* .. Executable Statements ..
*
* Initialize RESULT (in case N=0)
*
RESULT( 1 ) = ZERO
RESULT( 2 ) = ZERO
IF( N.LE.0 )
$ RETURN
*
UNFL = SLAMCH( 'Safe minimum' )
ULP = SLAMCH( 'Precision' )
*
ITRNSE = 0
ITRNSW = 0
NORMA = 'O'
NORME = 'O'
*
IF( LSAME( TRANSA, 'T' ) .OR. LSAME( TRANSA, 'C' ) ) THEN
NORMA = 'I'
END IF
*
IF( LSAME( TRANSE, 'T' ) ) THEN
ITRNSE = 1
NORME = 'I'
ELSE IF( LSAME( TRANSE, 'C' ) ) THEN
ITRNSE = 2
NORME = 'I'
END IF
*
IF( LSAME( TRANSW, 'C' ) ) THEN
ITRNSW = 1
END IF
*
* Normalization of E:
*
ENRMIN = ONE / ULP
ENRMAX = ZERO
IF( ITRNSE.EQ.0 ) THEN
DO 20 JVEC = 1, N
TEMP1 = ZERO
DO 10 J = 1, N
TEMP1 = MAX( TEMP1, ABS( REAL( E( J, JVEC ) ) )+
$ ABS( AIMAG( E( J, JVEC ) ) ) )
10 CONTINUE
ENRMIN = MIN( ENRMIN, TEMP1 )
ENRMAX = MAX( ENRMAX, TEMP1 )
20 CONTINUE
ELSE
DO 30 JVEC = 1, N
RWORK( JVEC ) = ZERO
30 CONTINUE
*
DO 50 J = 1, N
DO 40 JVEC = 1, N
RWORK( JVEC ) = MAX( RWORK( JVEC ),
$ ABS( REAL( E( JVEC, J ) ) )+
$ ABS( AIMAG( E( JVEC, J ) ) ) )
40 CONTINUE
50 CONTINUE
*
DO 60 JVEC = 1, N
ENRMIN = MIN( ENRMIN, RWORK( JVEC ) )
ENRMAX = MAX( ENRMAX, RWORK( JVEC ) )
60 CONTINUE
END IF
*
* Norm of A:
*
ANORM = MAX( CLANGE( NORMA, N, N, A, LDA, RWORK ), UNFL )
*
* Norm of E:
*
ENORM = MAX( CLANGE( NORME, N, N, E, LDE, RWORK ), ULP )
*
* Norm of error:
*
* Error = AE - EW
*
CALL CLASET( 'Full', N, N, CZERO, CZERO, WORK, N )
*
JOFF = 0
DO 100 JCOL = 1, N
IF( ITRNSW.EQ.0 ) THEN
WTEMP = W( JCOL )
ELSE
WTEMP = CONJG( W( JCOL ) )
END IF
*
IF( ITRNSE.EQ.0 ) THEN
DO 70 JROW = 1, N
WORK( JOFF+JROW ) = E( JROW, JCOL )*WTEMP
70 CONTINUE
ELSE IF( ITRNSE.EQ.1 ) THEN
DO 80 JROW = 1, N
WORK( JOFF+JROW ) = E( JCOL, JROW )*WTEMP
80 CONTINUE
ELSE
DO 90 JROW = 1, N
WORK( JOFF+JROW ) = CONJG( E( JCOL, JROW ) )*WTEMP
90 CONTINUE
END IF
JOFF = JOFF + N
100 CONTINUE
*
CALL CGEMM( TRANSA, TRANSE, N, N, N, CONE, A, LDA, E, LDE, -CONE,
$ WORK, N )
*
ERRNRM = CLANGE( 'One', N, N, WORK, N, RWORK ) / ENORM
*
* Compute RESULT(1) (avoiding under/overflow)
*
IF( ANORM.GT.ERRNRM ) THEN
RESULT( 1 ) = ( ERRNRM / ANORM ) / ULP
ELSE
IF( ANORM.LT.ONE ) THEN
RESULT( 1 ) = ( MIN( ERRNRM, ANORM ) / ANORM ) / ULP
ELSE
RESULT( 1 ) = MIN( ERRNRM / ANORM, ONE ) / ULP
END IF
END IF
*
* Compute RESULT(2) : the normalization error in E.
*
RESULT( 2 ) = MAX( ABS( ENRMAX-ONE ), ABS( ENRMIN-ONE ) ) /
$ ( REAL( N )*ULP )
*
RETURN
*
* End of CGET22
*
END
|