1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
* =========== DOCUMENTATION ===========
*
* Online html documentation available at
* http://www.netlib.org/lapack/explore-html/
*
* Definition:
* ===========
*
* SUBROUTINE DBDT05( M, N, A, LDA, S, NS, U, LDU,
* VT, LDVT, WORK, RESID )
*
* .. Scalar Arguments ..
* INTEGER LDA, LDU, LDVT, N, NS
* DOUBLE PRECISION RESID
* ..
* .. Array Arguments ..
* DOUBLE PRECISION D( * ), E( * ), S( * ), U( LDU, * ),
* $ VT( LDVT, * ), WORK( * )
* ..
*
*
*> \par Purpose:
* =============
*>
*> \verbatim
*>
*> DBDT05 reconstructs a bidiagonal matrix B from its (partial) SVD:
*> S = U' * B * V
*> where U and V are orthogonal matrices and S is diagonal.
*>
*> The test ratio to test the singular value decomposition is
*> RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS )
*> where VT = V' and EPS is the machine precision.
*> \endverbatim
*
* Arguments:
* ==========
*
*> \param[in] M
*> \verbatim
*> M is INTEGER
*> The number of rows of the matrices A and U.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*> N is INTEGER
*> The number of columns of the matrices A and VT.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*> A is DOUBLE PRECISION array, dimension (LDA,N)
*> The m by n matrix A.
*>
*> \param[in] LDA
*> \verbatim
*> LDA is INTEGER
*> The leading dimension of the array A. LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in] S
*> \verbatim
*> S is DOUBLE PRECISION array, dimension (NS)
*> The singular values from the (partial) SVD of B, sorted in
*> decreasing order.
*> \endverbatim
*>
*> \param[in] NS
*> \verbatim
*> NS is INTEGER
*> The number of singular values/vectors from the (partial)
*> SVD of B.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*> U is DOUBLE PRECISION array, dimension (LDU,NS)
*> The n by ns orthogonal matrix U in S = U' * B * V.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*> LDU is INTEGER
*> The leading dimension of the array U. LDU >= max(1,N)
*> \endverbatim
*>
*> \param[in] VT
*> \verbatim
*> VT is DOUBLE PRECISION array, dimension (LDVT,N)
*> The n by ns orthogonal matrix V in S = U' * B * V.
*> \endverbatim
*>
*> \param[in] LDVT
*> \verbatim
*> LDVT is INTEGER
*> The leading dimension of the array VT.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*> WORK is DOUBLE PRECISION array, dimension (M,N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*> RESID is DOUBLE PRECISION
*> The test ratio: norm(S - U' * A * V) / ( n * norm(A) * EPS )
*> \endverbatim
*
* Authors:
* ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2011
*
*> \ingroup double_eig
*
* =====================================================================
SUBROUTINE DBDT05( M, N, A, LDA, S, NS, U, LDU,
$ VT, LDVT, WORK, RESID )
*
* -- LAPACK test routine (version 3.4.0) --
* -- LAPACK is a software package provided by Univ. of Tennessee, --
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
* November 2011
*
* .. Scalar Arguments ..
CHARACTER UPLO
INTEGER LDA, LDU, LDVT, M, N, NS
DOUBLE PRECISION RESID
* ..
* .. Array Arguments ..
DOUBLE PRECISION A( LDA, * ), S( * ), U( LDU, * ),
$ VT( LDVT, * ), WORK( * )
* ..
*
* ======================================================================
*
* .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
* ..
* .. Local Scalars ..
INTEGER I, J
DOUBLE PRECISION ANORM, EPS
* ..
* .. External Functions ..
LOGICAL LSAME
INTEGER IDAMAX
DOUBLE PRECISION DASUM, DLAMCH, DLANGE
EXTERNAL LSAME, IDAMAX, DASUM, DLAMCH, DLANGE
* ..
* .. External Subroutines ..
EXTERNAL DGEMM
* ..
* .. Intrinsic Functions ..
INTRINSIC ABS, DBLE, MAX, MIN
* ..
* .. Executable Statements ..
*
* Quick return if possible.
*
RESID = ZERO
IF( MIN( M, N ).LE.0 .OR. NS.LE.0 )
$ RETURN
*
EPS = DLAMCH( 'Precision' )
ANORM = DLANGE( 'M', M, N, A, LDA, WORK )
*
* Compute U' * A * V.
*
CALL DGEMM( 'N', 'T', M, NS, N, ONE, A, LDA, VT,
$ LDVT, ZERO, WORK( 1+NS*NS ), M )
CALL DGEMM( 'T', 'N', NS, NS, M, -ONE, U, LDU, WORK( 1+NS*NS ),
$ M, ZERO, WORK, NS )
*
* norm(S - U' * B * V)
*
J = 0
DO 10 I = 1, NS
WORK( J+I ) = WORK( J+I ) + S( I )
RESID = MAX( RESID, DASUM( NS, WORK( J+1 ), 1 ) )
J = J + NS
10 CONTINUE
*
IF( ANORM.LE.ZERO ) THEN
IF( RESID.NE.ZERO )
$ RESID = ONE / EPS
ELSE
IF( ANORM.GE.RESID ) THEN
RESID = ( RESID / ANORM ) / ( DBLE( N )*EPS )
ELSE
IF( ANORM.LT.ONE ) THEN
RESID = ( MIN( RESID, DBLE( N )*ANORM ) / ANORM ) /
$ ( DBLE( N )*EPS )
ELSE
RESID = MIN( RESID / ANORM, DBLE( N ) ) /
$ ( DBLE( N )*EPS )
END IF
END IF
END IF
*
RETURN
*
* End of DBDT05
*
END
|
